Encontrar los tipos de datos de una tabla temporal SQL

Question

Necesito cambiar de usar una tabla #temp a una variable @table para poder usarlo en una función.

Mi consulta utiliza insertar en #temp (de varias tablas), así:

SELECT 
    a.col1, 
    a.col2, 
    b.col1... 
INTO #temp 
FROM ... 

¿Hay una manera fácil de averiguar los tipos de datos de las columnas en la tabla #temp para que pueda crear la variable @table con las mismas columnas y tipos de datos que #temp?

Answer 1

EXEC tempdb.dbo.sp_help N'#temp'; 

o

SELECT * 
    FROM tempdb.sys.columns 
    WHERE [object_id] = OBJECT_ID(N'tempdb..#temp'); 

Answer 2

Sí, los tipos de datos de la tabla temporal serán los tipos de datos de las columnas que está seleccionando e insertando en ella. Así que solo mire la declaración de selección y determine cada tipo de datos según la columna que seleccione.

Answer 3

me gustaría ir la ruta perezoso y uso

use tempdb 
GO 
EXECUTE sp_help #temp 

Answer 4

que necesita para calificar el proceso sp_help para ejecutar desde la base de datos tempdb para obtener detalles acerca de un hash tabla, porque ahí es donde realmente se almacena la tabla hash. Si intenta ejecutar sp_help desde una base de datos diferente, obtendrá un error de que la tabla no existe en esa base de datos.

Si la consulta se ejecuta fuera de tempdb, como supongo que es, puede ejecutar el siguiente:

exec tempdb..sp_help #temp 

Una ventaja de este procedimiento es que incluye una descripción textual de los tipos de datos de columna para ti. Esto hace que sea muy fácil copiar y pegar en otra consulta, p. si intentas usar la definición de una tabla temporal para crear una variable de tabla.

Puede encontrar la misma información en la tabla Syscolumns, pero le dará identificadores numéricos para los tipos que tendrá que mapear usted mismo. El uso de sp_help te ahorrará un paso.

Answer 5

Lo que intenta hacer es obtener información sobre los tipos de sistema de las columnas que está consultando.

Para SQL Server 2012 and later puede usar la función sys.dm_exec_describe_first_result_set. Se devuelve información detallada acerca de las columnas y el system_type_column contiene la definición completa tipo de sistema (listo para usar en su definición de la tabla):

Por ejemplo:

SELECT * 
FROM [sys].[dm_exec_describe_first_result_set] (N'SELECT object_id, name, type_desc FROM sys.indexes', null, 0); 

Answer 6

La respuesta aceptada hace no da el tipo de datos. Al asociar tempdb.sys.columns con sys.types, se obtiene el tipo de datos como se menciona en el comentario de la respuesta. Sin embargo, unir en system_type_id produce una fila adicional con el tipo de datos "sysname". En cambio, "user_type_id" da la solución exacta como se indica a continuación.

SELECT cols.NAME 
,ty.NAME 
FROM tempdb.sys.columns cols 
JOIN sys.types ty ON cols.user_type_id = ty.user_type_id 
WHERE object_id = OBJECT_ID('tempdb..#temp') 

Answer 7

Las otras respuestas le darán la información que necesita, pero todavía requieren que escriba todo hacia fuera cuando se define la variable de tabla.

El siguiente TSQL le permitirá generar rápidamente la definición de la variable de tabla para cualquier tabla dada.

Esto le puede ahorrar mucho tiempo en lugar de escribir manualmente las definiciones de mesa como:

table(Field1Name nvarchar(4), Field2Name nvarchar(20), Field3Name int 
, Field4Name numeric(28,12)) 

TSQL:

select top 10 * 
into #temp 
from db.dbo.myTable 



declare @tableName nvarchar(max) 
set @tableName = '#temp' 

use tempdb 
declare @tmp table(val nvarchar(max)) 
insert into @tmp 
select case data_type 
    when 'binary' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + cast(CHARACTER_MAXIMUM_LENGTH AS nvarchar(max)) + ')' 
    when 'char' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + cast(CHARACTER_MAXIMUM_LENGTH AS nvarchar(max)) + ')' 
    when 'datetime2' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + CAST(DATETIME_PRECISION as nvarchar(max)) + ')' 
    when 'datetimeoffset' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + CAST(DATETIME_PRECISION as nvarchar(max)) + ')' 
    when 'decimal' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + cast(NUMERIC_PRECISION as nvarchar(max)) + ',' + cast(NUMERIC_SCALE as nvarchar(max)) + ')' 
    when 'nchar' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + cast(CHARACTER_MAXIMUM_LENGTH AS nvarchar(max)) + ')' 
    when 'numeric' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + cast(NUMERIC_PRECISION as nvarchar(max)) + ',' + cast(NUMERIC_SCALE as nvarchar(max)) + ')' 
    when 'nvarchar' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + cast(CHARACTER_MAXIMUM_LENGTH AS nvarchar(max)) + ')' 
    when 'time' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + CAST(DATETIME_PRECISION as nvarchar(max)) + ')' 
    when 'varbinary' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + cast(CHARACTER_MAXIMUM_LENGTH AS nvarchar(max)) + ')' 
    when 'varchar' then COLUMN_NAME + ' ' + DATA_TYPE + '(' + cast(CHARACTER_MAXIMUM_LENGTH AS nvarchar(max)) + ')' 
    -- Most standard data types follow the pattern in the other section. 
    -- Non-standard datatypes include: binary, char, datetime2, datetimeoffset, decimal, nvchar, numeric, nvarchar, time, varbinary, and varchar 
    else COLUMN_NAME + ' ' + DATA_TYPE 

    end + case when IS_NULLABLE <> 'YES' then ' NOT NULL' else '' end 'dataType' 
    from INFORMATION_SCHEMA.COLUMNS 
where TABLE_NAME like @tableName + '%' 

declare @result nvarchar(max) 
set @result = '' 
select @result = @result + [val] + N',' 
from @tmp 
where val is not null 

set @result = substring(@result, 1, (LEN(@result)-1)) 

-- The following will replce '-1' with 'max' in order to properly handle nvarchar(max) columns 
set @result = REPLACE(@result, '-1', 'max') 
select @result 

Salida:

Field1Name nvarchar(4), Field2Name nvarchar(20), Field3Name int 
, Field4Name numeric(28,12) 

Answer 8

para obtener columnas nombrar con tipo de datos use este

EXEC tempdb.dbo.sp_help N'#temp'; 

o para obtener sólo por nombrar columnas para utilizar este

SELECT * 
FROM tempdb.sys.columns 
WHERE [object_id] = OBJECT_ID(N'tempdb..#temp');