Cómo detectar cuántas observaciones en un conjunto de datos (o si está vacío), en SAS?

Question

Me pregunto si hay una manera de detectar si un conjunto de datos está vacío, es decir, no tiene observaciones. O en otro refrán, cómo obtener el número de observaciones en un conjunto de datos específico.

Para que pueda escribir una instrucción If para establecer algunas condiciones.

Gracias.

Answer 1

Es fácil con PROC SQL. Haz un conteo y pon los resultados en una variable macro.

proc sql noprint; 
select count(*) into :observations from library.dataset; 
quit; 

Answer 2

Hay un montón de diferentes maneras, que tienden a utilizar una función macro con open() y attrn(). A continuación se muestra un ejemplo simple que funciona bien la mayor parte del tiempo. Si va a tratar con vistas de datos o situaciones más complejas como tener un conjunto de datos con registros marcados para eliminación o cláusulas where activas, entonces es posible que necesite una lógica más sólida.

%macro nobs(ds); 
    %let DSID=%sysfunc(OPEN(&ds.,IN)); 
    %let NOBS=%sysfunc(ATTRN(&DSID,NOBS)); 
    %let RC=%sysfunc(CLOSE(&DSID)); 
    &NOBS 
%mend; 

/* Here is an example */ 
%put %nobs(sashelp.class); 

Answer 3

Este es el ejemplo más completo del que hablaba @cmjohns. Devolverá 0 si está vacío, -1 si falta y tiene opciones para manejar las observaciones eliminadas y las cláusulas where (tenga en cuenta que el uso de una cláusula where puede hacer que la macro tome mucho tiempo en conjuntos de datos muy grandes).

Notas

de uso:

Esta macro devolverá el número de observaciones en un conjunto de datos. Si el conjunto de datos no existe, se devolverá -1. No recomendaría esto para su uso con nombres de libras ODBC, úsela solo en tablas SAS.

Parámetros:

• IDS - El libname.dataset que desea comprobar.
• iWhereClause (Opcional) - una cláusula WHERE de aplicar
• iNobsType (Opcional) - O NOBS O NLOBSF. Ver SASV9 documentation para descripciones.

definición de macro:

%macro nobs(iDs=, iWhereClause=1, iNobsType=nlobsf, iVerbose=1); 
    %local dsid nObs rc; 

    %if "&iWhereClause" eq "1" %then %do; 
    %let dsID = %sysfunc(open(&iDs)); 
    %end; 
    %else %do; 
    %let dsID = %sysfunc(open(&iDs(where=(&iWhereClause)))); 
    %end; 

    %if &dsID %then %do; 
    %let nObs = %sysfunc(attrn(&dsID,nlobsf)); 
    %let rc = %sysfunc(close(&dsID)); 
    %end; 
    %else %do; 
    %if &iVerbose %then %do; 
     %put WARNING: MACRO.NOBS.SAS: %sysfunc(sysmsg());  
    %end; 
    %let nObs = -1; 
    %end; 
    &nObs 
%mend; 

Ejemplo de Uso:

%put %nobs(iDs=sashelp.class); 
%put %nobs(iDs=sashelp.class, iWhereClause=height gt 60); 
%put %nobs(iDs=this_dataset_doesnt_exist); 

Resultados

19 
12 
-1 

instalación

recomiendo la creación de un SAS autocall library y la colocación de esta macro en su ubicación autocall.

Answer 4

Proc sql no es eficiente cuando tenemos un gran conjunto de datos.Aunque el uso de ATTRN es buen método, pero esto se puede lograr dentro de SAS base, aquí está la solución eficiente que puede dar el número de obs de incluso miles de filas con sólo leer una fila:

data DS1; 
set DS nobs=i; 
if _N_ =2 then stop; 
No_of_obs=i; 
run; 

Answer 5

El truco está produciendo una salida incluso cuando el conjunto de datos está vacío.

data CountObs; 

    i=1; 
    set Dataset_to_Evaluate point=i nobs=j; * 'point' avoids review of full dataset*; 
    No_of_obs=j; 
    output; * Produces a value before "stop" interrupts processing *; 
    stop; * Needed whenever 'point' is used *; 
    keep No_of_obs; 
run; 

proc print data=CountObs; 
run; 

El código anterior es la forma más sencilla que he encontrado para producir el número de observaciones, incluso cuando el conjunto de datos está vacía. He oído que NOBS puede ser complicado, pero lo anterior puede funcionar para aplicaciones simples.

Answer 6

Un enfoque ligeramente diferente:

proc contents data=library.dataset out=nobs; 
run; 

proc summary data=nobs nway; 
class nobs; 
var delobs; 
output out=nobs_summ sum=; 
run; 

Esto le dará un conjunto de datos con una observación; la variable nobs tiene el valor de número de observaciones en el conjunto de datos, incluso si es 0.

Answer 7

Creo que estoy tratando de reinventar la rueda aquí con tantas respuestas ya. Pero sí veo algunos otros métodos que intentan contar desde el conjunto de datos real; esto podría llevar mucho tiempo para grandes conjuntos de datos. Aquí hay un método más eficiente:

proc sql; 
select nlobs from sashelp.vtable where libname = "library" and memname="dataset"; 
quit;