Deseche su plantilla en f #

Question

He utilizado las bibliotecas Scrap Your Boilerplate y Uniplate en el lenguaje de programación Haskell, y me parece que esta forma de programación genérica sobre las uniones discriminadas es realmente útil. ¿Hay una biblioteca equivalente en el lenguaje de programación f #?

Answer 1

No es que yo sepa; sin compatibilidad incorporada al lenguaje/compilador, espero que la única alternativa sea una versión basada en la reflexión. (No sé cómo se implementa Uniplate, ¿verdad?)

Aquí está el código de una versión basada en la reflexión basada en el ejemplo de la presentación original. No he pensado profundamente acerca de sus limitaciones, pero esto fue mucho más simple de lo que hubiera imaginado.

type Company = C of Dept list 
and Dept = D of Name * Manager * SubUnit list 
and SubUnit = | PU of Employee | DU of Dept 
and Employee = E of Person * Salary 
and Person = P of Name * Address 
and Salary = S of float 
and Manager = Employee 
and Name = string 
and Address = string 

let data = C [D("Research",E(P("Fred","123 Rose"),S 10.0), 
        [PU(E(P("Bill","15 Oak"),S 5.0))])] 
printfn "%A" data 

open Microsoft.FSharp.Reflection 
let everywhere<'a,'b>(f:'a->'a, src:'b) = // ' 
    let ft = typeof<'a>    // ' 
    let rec traverse (o:obj) = 
     let ot = o.GetType() 
     if ft = ot then 
      f (o :?> 'a) |> box // ' 
     elif FSharpType.IsUnion(ot) then 
      let info,vals = FSharpValue.GetUnionFields(o, ot) 
      FSharpValue.MakeUnion(info, vals |> Array.map traverse) 
     else 
      o 
    traverse src :?> 'b  // ' 

let incS (S x) = S(x+1.0) 

let newData = everywhere(incS, data) 
printfn "%A" newData 

La función everywhere atraviesa toda la estructura de un DU arbitraria y aplica la función f a cada nodo que es el tipo que f funciona en, dejando todos los demás nodos como está.