colocar una imagen en el plano XY en un gráfico 3D en Mathematica

Question

favor considere lo siguiente, entre los siguientes partir

Can we generate "foveated Image" in Mathematica

Clear[acuity]; 

acuity[distance_, x_, y_, blindspotradius_] := 

With[{\[Theta] = ArcTan[distance, Sqrt[x^2 + y^2]]}, 
     Clip[(Chop@Exp[-Abs[\[Theta]]/(15. Degree)] - .05)/.95, 
        {0,1}] (1.-Boole[(x + 100.)^2 + y^2 <= blindspotradius^2])] 

Plot3D[acuity[250., x, y, 9], {x, -256, 256}, {y, -256, 256}, 
PlotRange -> All, Axes -> False, PlotPoints -> 40, 
ExclusionsStyle -> Automatic, Boxed -> False, Mesh -> None] 

¿Cómo podría añadir la foto a continuación en el plano X & Y. Luego haz que la superficie se represente transparente. ¿Es posible? (imagen obtenida con una solución en la pregunta mencionada anteriormente).

Answer 1

i = Import["http://i.stack.imgur.com/0EizO.png"]; 
p = {{0, 0}, {1, 0}, {1, 1}, {0, 1}}; 
Show@{ 
    Plot3D[ 
    acuity[250., x, y, 9], {x, -256, 256}, {y, -256, 256}, 
    PlotRange -> All, PlotPoints -> 40,ExclusionsStyle -> Automatic,Axes -> False, 
    Boxed -> False, Mesh -> None, PlotStyle -> Directive[Opacity[0.5]]], 
    Graphics3D[{Texture[i], 
    Polygon[Join[#, {0}] & /@ (2 p - 1) 256, VertexTextureCoordinates -> p]} 
    ]} 

Editar

Tratar con AspectRatio [], conforme a lo solicitado en sus comentarios:

p = {{0, 0}, {1, 0}, {1, 1}, {0, 1}}; 
r = First@#/Last@# &@Dimensions@ImageData@i; 
a = 1.4; 
Show@{Plot3D[ 
     acuity[250., a x, a y, 9], {x, -256 , 256 }, {y, -256 r , 256 r }, 
      PlotRange -> All, PlotPoints -> 40, ExclusionsStyle -> Automatic, 
      Axes -> False, Boxed -> False, Mesh -> None, 
      PlotStyle -> Directive[Opacity[0.5]], AspectRatio -> r], 
    Graphics3D[{Texture[i], 
      Polygon[{{-256 , -256 r, 0}, { 256 , -256 r , 0}, 
         { 256 , 256 r, 0}, {-256 , 256 r, 0}}, 
      VertexTextureCoordinates -> p]}]}