¿Es posible escribir texto en richtextbox en tiempo de diseño?

Question

Tengo un System.Windows.Forms.RichTextBox que deseo usar para mostrar algunas instrucciones a los usuarios de mi aplicación.

¿Es posible configurar algo del texto que ingresé en designtime para que sea negrita?

¿O no tengo más opción que hacerlo en tiempo de ejecución?

Answer 1

Puede ciertamente crear un documento RTF en el editor RTF (por ejemplo, WordPad), guardar el archivo, abrirlo como un archivo de texto/plano y copiar el documento RTF en la propiedad RtfText de su RichTextBox en el momento del diseño.

Pero desaconsejo. De esta forma, tienes una gran cantidad de datos en tu código y no tiene sentido hacerlo. Usa un recurso, para eso están ahí, después de todo. Puede vincular recursos individuales para controlar propiedades en tiempo de diseño.

Answer 2

Agregue una nueva clase a su proyecto y pegue el código que se muestra a continuación. Compilar. Coloque el nuevo control desde la parte superior de la caja de herramientas en su formulario. Seleccione la propiedad RichText y haga clic en el botón con los puntos. Eso iniciará Wordpad. Edite su texto, escriba Ctrl + S y cierre Wordpad. Tenga en cuenta que el diseñador de Visual Studio no funciona cuando Wordpad está abierto.

Imports System.ComponentModel 
Imports System.Drawing.Design 
Imports System.IO 
Imports System.Diagnostics 

Public Class MyRtb 
    Inherits RichTextBox 

    <Editor(GetType(RtfEditor), GetType(UITypeEditor))> _ 
    Public Property RichText() As String 
     Get 
      Return MyBase.Rtf 
     End Get 
     Set(ByVal value As String) 
      MyBase.Rtf = value 
     End Set 
    End Property 

End Class 

Friend Class RtfEditor 
    Inherits UITypeEditor 

    Public Overrides Function GetEditStyle(ByVal context As ITypeDescriptorContext) As UITypeEditorEditStyle 
     Return UITypeEditorEditStyle.Modal 
    End Function 

    Public Overrides Function EditValue(ByVal context As ITypeDescriptorContext, ByVal provider As IServiceProvider, ByVal value As Object) As Object 
     Dim fname As String = Path.Combine(Path.GetTempPath, "text.rtf") 
     File.WriteAllText(fname, CStr(value)) 
     Process.Start("wordpad.exe", fname).WaitForExit() 
     value = File.ReadAllText(fname) 
     File.Delete(fname) 
     Return value 
    End Function 
End Class 

Answer 3

He encontrado este enlace en CodeProject a ser muy útil:

http://www.codeproject.com/KB/miscctrl/richtextboxextended.aspx

Es una acumulación de trabajo totalmente el control de edición de RTF alrededor del control RichtTextBox .net estándar con un buen código estructurado. Muestra cómo usar casi todas las funciones disponibles del control.

Sin embargo, está escrito en C# y no en vb.net, pero definitivamente debe echar un vistazo.

Answer 4

Bravo - ¡simple y eficiente! Aquí también hay una pequeña corrección, porque el argumento es una cadena larga con espacios, por lo que la siguiente línea contiene las comillas requeridas:

Process.Start("wordpad.exe", """" & fname & """").WaitForExit()