Guardar archivo XML en AS3 es posible

Question

var xml:XML = <myXml> 
        <item prop="1" /> 
        <item prop="2" /> 
       </myXml>; 

Necesito guardar como archivo xml en el disco duro local (directorio del proyecto).

¿Es posible guardar en as3?

Answer 1

si desea almacenarlo localmente (en la PC del cliente), puede utilizar un objeto compartido local. Consulte este tutorial

Answer 2

Lo siento, su pregunta no es muy clara.

¿Está preguntando si puede guardar un archivo en el disco duro desde un archivo SWF de compilación escrito en AS3?

¿O está preguntando si puede incluir un archivo XML sin formato en su proyecto AS3 sin necesidad de escribirlo como una variable?

Si se refería a lo primero, no, sin Adobe AIR. Puede guardar datos localmente como SharedObject, pero no como un archivo arbitrario en el sistema de archivos.

En este último caso, entonces sí: debe incrustar el archivo tal como lo haría con otro recurso (como una imagen o un sonido). Sin embargo, parece que podría haber un error en Flash que hace que esto no sea trivial para descubrir cómo hacerlo.

This link might be of help to you.

[Embed(source='../../../../assets/levels/test.xml', mimeType="application/octet-stream")] 
public static const Level_Test:Class; 

Y luego a analizar el código XML:

var ba:ByteArray = (new Levels.Level_Test()) as ByteArray; 
var s:String = ba.readUTFBytes(ba.length); 
xml = new XML(s); 

Disculpas si ninguna de estas preguntas son lo que eran en realidad pidiendo.

¡Salud!

Answer 3

Tiré esto, y de hecho lo puedes guardar en .XML usando lo siguiente como ejemplo minimalista.

package com.hodgedev.xmlcreator 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 
    import flash.utils.ByteArray; 
    import flash.net.FileReference; 

/** 
* ... 
* @author Brian Hodge (brian@hodgedev.com) 
*/ 
public class Main extends Sprite 
{ 
    private var _xml:XML; 

    public function Main():void 
    { 
     if (stage) init(); 
     else addEventListener(Event.ADDED_TO_STAGE, init); 
    } 

    private function init(e:Event = null):void 
    { 
     removeEventListener(Event.ADDED_TO_STAGE, init); 

     //Calling the save method requires user interaction and Flash Player 10 
     stage.addEventListener(MouseEvent.MOUSE_DOWN, _onMouseDown); 

     _xml= <xml> 
       <test>data</test> 
       </xml>; 
    } 
    private function _onMouseDown(e:MouseEvent):void 
    { 
     var ba:ByteArray = new ByteArray(); 
     ba.writeUTFBytes(_xml); 
     //ba. 

     var fr:FileReference = new FileReference(); 
     fr.addEventListener(Event.SELECT, _onRefSelect); 
     fr.addEventListener(Event.CANCEL, _onRefCancel); 

     fr.save(ba, "filename.xml"); 
    } 
    private function _onRefSelect(e:Event):void 
    { 
     trace('select'); 
    } 
    private function _onRefCancel(e:Event):void 
    { 
     trace('cancel'); 
    } 
} 

}

hay algunas cosas a tener en cuenta.

• Se requieren Flash Player 10 para usar el método de la clase FileReference guardar.
• Para hacer cualquier cosa que INVOQUE un aviso, Flash requiere la interacción del usuario como la entrada del teclado o del mouse.

En lo anterior escucho el MouseEvent.MOUSE_DOWN en el escenario para que sirva como la INTERACCIÓN DEL USUARIO que se requiere para invocar el aviso de guardado.

I fijó una estructura XML básica dentro del código (esto normalmente vendrá desde una fuente externa y no tendrán ningún problema en ambos sentidos.

se crea un ByteArray y el XML se escribe en el ByteArray.

El método de guardado de la clase FileReference requiere un ByteArray y el nombre guardado predeterminado se pasa como los dos parámetros.

Espero que esto ayude.