Obteniendo cada enésimo elemento de una secuencia

Question

Estoy buscando una manera de crear una secuencia que consta de cada enésimo elemento de otra secuencia, pero no parece encontrar una manera de hacerlo de una manera elegante. Por supuesto, puedo hackear algo, pero me pregunto si hay una función de biblioteca que no estoy viendo.

Las funciones de secuencia cuyos nombres terminan en -i parecen ser bastante buenas para determinar cuándo un elemento es el enésimo o (múltiplo de n) uno, pero solo puedo ver iteri y mapi, ninguno de lo cual realmente se presta a la tarea.

Ejemplo:

let someseq = [1;2;3;4;5;6] 
let partial = Seq.magicfunction 3 someseq 

Entonces partial debería ser [3;6]. ¿Hay algo así por ahí?

Editar:

Si no soy tan ambicioso y permitir la n a ser constante/conocido, entonces me acaba de encontrar que el siguiente debería funcionar:

let rec thirds lst = 
    match lst with 
    | _::_::x::t -> x::thirds t // corrected after Tomas' comment 
    | _ -> [] 

Would ¿Hay alguna forma de escribir esto más corto?

Answer 1

se puede obtener el comportamiento mediante la composición de mapi con otras funciones:

let everyNth n seq = 
    seq |> Seq.mapi (fun i el -> el, i)    // Add index to element 
     |> Seq.filter (fun (el, i) -> i % n = n - 1) // Take every nth element 
     |> Seq.map fst        // Drop index from the result 

la solución usando opciones y choose según lo sugerido por Annon utilizaría sólo dos funciones, pero el cuerpo de la primera sería un poco más complicado (pero el principio es esencialmente el mismo).

Una versión más eficiente utilizando directamente el objeto IEnumerator no es demasiado difícil escribir:

let everyNth n (input:seq<_>) = 
    seq { use en = input.GetEnumerator() 
     // Call MoveNext at most 'n' times (or return false earlier) 
     let rec nextN n = 
      if n = 0 then true 
      else en.MoveNext() && (nextN (n - 1)) 
     // While we can move n elements forward... 
     while nextN n do 
      // Retrun each nth element 
      yield en.Current } 

EDIT: El fragmento también está disponible aquí: http://fssnip.net/1R

Answer 2

Seq.choose funciona muy bien en estas situaciones porque le permite hacer el trabajo filter dentro del mapi lambda.

let everyNth n elements = 
    elements 
    |> Seq.mapi (fun i e -> if i % n = n - 1 then Some(e) else None) 
    |> Seq.choose id 

Similar a here.