VBA: Condicional - no es nada

Question

Hay una condición If en una aplicación de VBA como se ve a continuación:

If Not My_Object Is Nothing Then 
My_Object.Compute 

Cuando el código se ejecuta en modo de depuración, he encontrado que la condición If devuelve un cierto incluso cuando My_Object tiene "No Variables".

¿Podría alguien explicar esto? Quiero que My_Object.Compute se ejecute solo cuando existe My_Object.

Answer 1

Basado en su comentario a Issun:

Gracias por la explicación. En mi caso, el objeto se declara y crea antes de la condición If. Entonces, ¿cómo uso la condición If para verificar < Sin variables>? En otras palabras, no quiero para ejecutar My_Object.Compute si mi_objeto tiene < ninguna variable>

Es necesario comprobar una de las propiedades del objeto. Sin decirnos cuál es el objeto, no podemos ayudarte.

Probé varios objetos comunes y descubrí que una instancia de Collection sin elementos añadidos muestra <No Variables> en la ventana del reloj. Si el objeto es de hecho una colección, se puede comprobar por la condición <No Variables> utilizando la propiedad .Count:

Sub TestObj() 
Dim Obj As Object 
    Set Obj = New Collection 
    If Obj Is Nothing Then 
     Debug.Print "Object not instantiated" 
    Else 
     If Obj.Count = 0 Then 
      Debug.Print "<No Variables> (ie, no items added to the collection)" 
     Else 
      Debug.Print "Object instantiated and at least one item added" 
     End If 
    End If 
End Sub 

---

También vale la pena señalar que si se declara un objeto As New entonces el cheque Is Nothing se vuelve inútil. La razón es que cuando declaras un objeto As New, se crea automáticamente cuando se llama por primera vez, ¡incluso si la primera vez que llamas es para ver si existe!

Dim MyObject As New Collection 
If MyObject Is Nothing Then ' <--- This check always returns False 

Esto no parece ser la causa de su problema específico. Pero, dado que otros pueden encontrar esta pregunta a través de una búsqueda en Google, quería incluirla porque es un error común para principiantes.

Answer 2

Simplemente porque su objeto de clase no tiene variables no significa que no sea nada. Declarar y objeto y crear un objeto son dos cosas diferentes. Mire y vea si está configurando/creando el objeto.

Tomemos por ejemplo el objeto de diccionario: simplemente porque no contiene variables no significa que no se haya creado.

Sub test() 

Dim dict As Object 
Set dict = CreateObject("scripting.dictionary") 

If Not dict Is Nothing Then 
    MsgBox "Dict is something!" '<--- This shows 
Else 
    MsgBox "Dict is nothing!" 
End If 

End Sub 

Sin embargo, si declara un objeto pero nunca lo crea, no es nada.

Sub test() 

Dim temp As Object 

If Not temp Is Nothing Then 
    MsgBox "Temp is something!" 
Else 
    MsgBox "Temp is nothing!" '<---- This shows 
End If 

End Sub 

Answer 3

En mi código de ejemplo, estaba configurando my object en nada, y no pude obtener la parte "no" de la instrucción if para trabajar con el objeto. Intenté if My_Object is not nothing y también if not My_Object is nothing. Puede ser sólo una cosa sintaxis no puedo averiguar pero no tenía tiempo para perder el tiempo, así que lo hice un poco de solución como esta:

if My_Object is Nothing Then 
    'do nothing 
Else 
    'Do something 
End if