Access 2010 VBA consulta una tabla y repite los resultados

Question

Tengo una consulta que deseo ejecutar en una tabla. Con los resultados, quiero hacer algo. En mi cabeza, el pseudo código es:

var q = "select * from table where some condition"; 
var results = db.getResults(q); 
foreach (row r in results) 
    do something with result 

¿Qué tal algo similar con vba?

Answer 1

DAO es nativa a acceder y, con mucho, el mejor para el uso general. ADO tiene su lugar, pero es poco probable que sea esto.

Dim rs As DAO.Recordset 
Dim db As Database 
Dim strSQL as String 

Set db=CurrentDB 

strSQL = "select * from table where some condition" 

Set rs = db.OpenRecordset(strSQL) 

Do While Not rs.EOF 

    rs.Edit 
    rs!SomeField = "Abc" 
    rs!OtherField = 2 
    rs!ADate = Date() 
    rs.Update 

    rs.MoveNext 
Loop 

Answer 2

Sé que algunas cosas han cambiado en AC 2010. Sin embargo, el ADODB anticuado es, hasta donde sé, el mejor camino a seguir en VBA. Un ejemplo:

Dim cn As ADODB.Connection 
Dim cmd As ADODB.Command 
Dim prm As ADODB.Parameter 
Dim rs As ADODB.Recordset 
Dim colReturn As New Collection 

Dim SQL As String 
SQL = _ 
    "SELECT c.ClientID, c.LastName, c.FirstName, c.MI, c.DOB, c.SSN, " & _ 
    "c.RaceID, c.EthnicityID, c.GenderID, c.Deleted, c.RecordDate " & _ 
    "FROM tblClient AS c " & _ 
    "WHERE c.ClientID = @ClientID" 

Set cn = New ADODB.Connection 
Set cmd = New ADODB.Command 

With cn 
    .Provider = DataConnection.MyADOProvider 
    .ConnectionString = DataConnection.MyADOConnectionString 
    .Open 
End With 

With cmd 
    .CommandText = SQL 
    .ActiveConnection = cn 
    Set prm = .CreateParameter("@ClientID", adInteger, adParamInput, , mlngClientID) 
    .Parameters.Append prm 
End With 

Set rs = cmd.Execute 

With rs 
    If Not .EOF Then 
     Do Until .EOF 
      mstrLastName = Nz(!LastName, "") 
      mstrFirstName = Nz(!FirstName, "") 
      mstrMI = Nz(!MI, "") 
      mdDOB = !DOB 
      mstrSSN = Nz(!SSN, "") 
      mlngRaceID = Nz(!RaceID, -1) 
      mlngEthnicityID = Nz(!EthnicityID, -1) 
      mlngGenderID = Nz(!GenderID, -1) 
      mbooDeleted = Deleted 
      mdRecordDate = Nz(!RecordDate, "") 

      .MoveNext 
     Loop 
    End If 
    .Close 
End With 

cn.Close 

Set rs = Nothing 
Set cn = Nothing 

Answer 3

Ahh. Porque me perdí el punto de tu publicación inicial, aquí hay un ejemplo que también ITERATES. El primer ejemplo no. En este caso, recupero un conjunto de registros ADODB y luego cargo los datos en una colección, que devuelve la función al código del cliente:

EDITAR: No estoy seguro de qué cometí al pegar el código, pero el formateo es pequeña screwball. ¡Lo siento!

Public Function StatesCollection() As Collection 
Dim cn As ADODB.Connection 
Dim cmd As ADODB.Command 
Dim rs As ADODB.Recordset 
Dim colReturn As New Collection 

Set colReturn = New Collection 

Dim SQL As String 
SQL = _ 
    "SELECT tblState.State, tblState.StateName " & _ 
    "FROM tblState" 

Set cn = New ADODB.Connection 
Set cmd = New ADODB.Command 

With cn 
    .Provider = DataConnection.MyADOProvider 
    .ConnectionString = DataConnection.MyADOConnectionString 
    .Open 
End With 

With cmd 
    .CommandText = SQL 
    .ActiveConnection = cn 
End With 

Set rs = cmd.Execute 

With rs 
    If Not .EOF Then 
    Do Until .EOF 
     colReturn.Add Nz(!State, "") 
     .MoveNext 
    Loop 
    End If 
    .Close 
End With 
cn.Close 

Set rs = Nothing 
Set cn = Nothing 

Set StatesCollection = colReturn 

End Function