¿Puedo obtener una consulta fila por índice en ColdFusion?

Question

Quiero obtener una fila específica en un objeto ColdFusion Query sin hacer un bucle sobre ella.

me gustaría hacer algo como esto:

<cfquery name="QueryName" datasource="ds"> 
SELECT * 
FROM tablename 
</cfquery> 

<cfset x = QueryName[5]> 

Pero me da un error diciendo que la consulta no es indexable por "5". Sé de hecho que hay más de 5 registros en esta consulta.

Answer 1

No se puede obtener una fila en CF < = 10. Debe obtener una columna específica.

<cfset x = QueryName.columnName[5]> 

Han pasado 8 años desde que he publicado esta respuesta, sin embargo. Aparentemente CF11 finalmente implementó esa característica. Ver FrankieZ's answer.

Answer 2

usted tiene que convertir la consulta a una estructura en primer lugar:

<cfscript> 
    function GetQueryRow(query, rowNumber) { 
     var i = 0; 
     var rowData = StructNew(); 
     var cols = ListToArray(query.columnList); 
     for (i = 1; i lte ArrayLen(cols); i = i + 1) { 
      rowData[cols[i]] = query[cols[i]][rowNumber]; 
     } 
     return rowData; 
    } 
</cfscript> 

<cfoutput query="yourQuery"> 
    <cfset theCurrentRow = GetQueryRow(yourQuery, currentRow)> 
    <cfdump var="#theCurrentRow#"> 
</cfoutput> 

espero que esto le apunta en la dirección correcta.

Answer 3

Sé que vuelvo a este hilo cada vez que Google "notación de partición cfquery". Aquí hay una función que escribí para manejar este caso usando la notación de corchetes. Espero que esto puede ayudar a alguien más también:

<cffunction name="QueryGetRow" access="public" returntype="array" hint="I return the specified row's data as an array in the correct order"> 
    <cfargument name="query" required="true" type="query" hint="I am the query whose row data you want"> 
    <cfargument name="rowNumber" required="true" hint="This is the row number of the row whose data you want"> 

    <cfset returnArray = []> 
    <cfset valueArray = []> 

    <cfset cList = ListToArray(query.ColumnList)> 
    <cfloop from="1" to="#ArrayLen(cList)#" index="i"> 
     <cfset row = query["#cList[i]#"][rowNumber]> 
     <cfset row = REReplace(row, "(,)", " ")> 
     <cfset returnArray[i] = row> 
     <cfset i++> 
    </cfloop> 
    <cfreturn returnArray> 
</cffunction> 

El REReplace es opcional, lo tengo ahí para limpiar comas para que no arruine la función arrayToList más adelante si usted tiene que usarlo.

Answer 4

Quería extraer una sola fila de una consulta y mantener los nombres de las columnas (por supuesto). Se trata de cómo lo resolví:

<cffunction name="getQueryRow" returntype="query" output="no"> 
    <cfargument name="qry" type="query" required="yes"> 
    <cfargument name="row" type="numeric" required="yes"> 
    <cfset arguments.qryRow=QueryNew(arguments.qry.columnlist)> 
    <cfset QueryAddRow(arguments.qryRow)> 
    <cfloop list="#arguments.qry.columnlist#" index="arguments.column"> 
     <cfset QuerySetCell(arguments.qryRow,arguments.column,Evaluate("arguments.qry.#arguments.column#[arguments.row]"))> 
    </cfloop> 
    <cfreturn arguments.qryRow> 
</cffunction> 

Answer 5

Creo que hay una solución más simple ... que supongo que sabes sus nombres de columna y sólo desea que esta columna o que uno. Entonces no necesitas poner toda la fila en una estructura. Puede hacer referencia a la consulta por número de fila (recuerde que su 1 no está basado en 0).

yourQueryName [ "yourColumnName "] [rowNumber]

<cfoutput> 
    #mycontacts["Name"][13]# 
    #mycontacts["HomePhone"][13]# 
</cfoutput> 

Answer 6

métodos previamente descritos para la obtención de datos de la consulta por nombre de columna y el número de fila (variables.myquery [" columnName"] [rowNumber ]) son correctos, pero no convenientes para obtener una fila completa de datos de consulta.

Estoy ejecutando Railo 4.1. Y esta es una buena solución. Lástima que esto no se puede hacer de la manera que quisiéramos obtener una fila completa de datos, pero el siguiente método nos permite obtener lo que queremos a través de algunos aros.

Cuando serializeJSON(variables.myquery) cambia la consulta a un objeto estructurado cfml con formato JSON con dos elementos: "Columnas" y "Datos". Ambas son matrices de datos. La matriz de "datos" es una matriz bidimensional para filas y luego datos columnares.

El problema es que ahora tenemos una cadena inutilizable. Entonces, si volvemos a serializarlo, NO es una consulta, sino una estructura regular utilizable en el formato descrito anteriormente.

Supongamos que ya tenemos una variable de consulta llamada 'variables.myquery'. A continuación, mira el siguiente código:

<cfset variables.myqueryobj = deserializeJSON(serializeJSON(variables.myquery)) /> 

Ahora usted tiene la matriz bidimensional consiguiendo este:

<cfset variables.allrowsarray = variables.myqueryobj.data /> 

y se obtiene una matriz fila consulta por conseguir esto:

<cfset variables.allrowsarray = variables.myqueryobj.data[1] /> 

O la última fila de esta manera:

<cfset variables.allrowsarray = variables.myqueryobj.data[variables.myquery.recordCount] /> 

y se puede obtener valores de las columnas individuales por número de orden de las columnas iteración:

<cfset variables.allrowsarray = variables.myqueryobj.data[1][1] /> 

Ahora bien, esto podría ser lento y posiblemente imprudente con grandes resultados de la consulta, pero esto es una solución fresca, no obstante.

Answer 7

Esto ahora se puede lograr de ColdFusion 11 a través de QueryGetRow

<cfquery name="myQuery" result="myresult" datasource="artGallery" fetchclientinfo="yes" > 
select * from art where ARTID > 
<cfqueryparam value="2" cfsqltype="CF_SQL_INTEGER"> 
</cfquery> 

<cfdump var="#myQuery#" > 

<cfset data = QueryGetRow(myQuery, 1) > 

<cfdump var="#data#" > 

Answer 8

Mira la documentación de queryGetRow. Acepta un objeto de consulta y un índice de la fila con la referencia de la primera fila con el índice de 1 (NO 0). Se requiere que el índice utilizado de esta forma sea un entero positivo.

<cfquery name="QueryName" datasource="ds"> 
    SELECT * 
    FROM tablename 
</cfquery> 

<!--- 
    This would retrieve the first record of the query 
    and store the record in a struct format in the variable 'x'. 
---> 
<cfset x = queryGetRow(QueryName, 1) /> 
<!--- 
    This is an alternative using the member method form of queryGetRow 
---> 
<cfset x = QueryName.getRow(1) />