¿Cómo buscar y reemplazar en odt Abrir documento de Office?

Question

En mi aplicación de Delphi estoy actualmente hacer Buscar & Reemplazar programáticamente para documentos de texto docx y docx utilizando Office ole automation. ¿Alguien tiene el código para hacer lo mismo (para doc, docs, odt) en OpenOffice?

También pedí un related question on saving to pdf.

Answer 1

Debe enfocarse en la interfaz XReplaceable. Aquí está el ejemplo. Tenga en cuenta que no hay manejo de errores. Lo probé con el escritor de LibreOffice y funciona bien para mí.

uses 
    ComObj; 

procedure OpenOfficeReplace(const AFileURL: string; ASearch: string; const AReplace: string); 
var 
    StarOffice: Variant; 
    StarDesktop: Variant; 
    StarDocument: Variant; 
    FileReplace: Variant; 
    FileParams: Variant; 
    FileProperty: Variant; 

begin 
    StarOffice := CreateOleObject('com.sun.star.ServiceManager'); 
    StarDesktop := StarOffice.CreateInstance('com.sun.star.frame.Desktop'); 

    FileParams := VarArrayCreate([0, 0], varVariant); 
    FileProperty := StarOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue'); 
    FileProperty.Name := 'Hidden'; 
    FileProperty.Value := False; 
    FileParams[0] := FileProperty; 

    StarDocument := StarDesktop.LoadComponentFromURL(AFileURL, '_blank', 0, FileParams); 

    FileReplace := StarDocument.CreateReplaceDescriptor; 
    FileReplace.SearchCaseSensitive := False; 
    FileReplace.SetSearchString(ASearch); 
    FileReplace.SetReplaceString(AReplace); 

    StarDocument.ReplaceAll(FileReplace); 

    ShowMessage('Replace has been finished'); 

    StarDocument.Close(True); 
    StarDesktop.Terminate; 
    StarOffice := Unassigned; 
end; 

Y el uso del ejemplo

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    OpenOfficeReplace('file:///C:/File.odt', 'Search', 'Replace'); 
end; 

También hay varias buscar/reemplazar opciones para SearchDescriptor.