calcule el mes del año y el número de semana en excel

Question

En Excel 2007 tengo un número de año y un número de semana y quiero calcular el número del mes.

El problema es que en mi caso el comienzo de cada semana es un lunes, por lo que algunas semanas se superpondrán con los años.

Ejemplos:

Year: 2012 
Week 1 started: Monday 2nd January 
Sunday 1st January was in week 52 of 2011 

Así dan el siguiente:

Year: 2011 
Week: 10 

¿Cómo puedo trabajar esa semana 10 se inició el 7 de marzo y por lo tanto la semana 10 fue el número de Mes 3.

Gracias por cualquier ayuda sobre esto.

Answer 1

I sugieren el siguiente enfoque

• determinar la (ISO) semana de 1 de enero (ver this page) [en la celda C4]

  =INT((B4-DATE(YEAR(B4-WEEKDAY(B4-1)+4),1,3)+WEEKDAY(DATE(YEAR(B4-WEEKDAY(B4-1)+4),1,3))+5)/7) (B4 suponiendo =DATE([Year],1,1))

• Calcule el día en que comienza la semana 1 [en la celda D4]

  =IF(C4=1,B4-WEEKDAY(B4,3),B4+7-WEEKDAY(B4,3))

• Determinar el lunes de la semana en cuestión y el mes correspondiente

  =MONTH(D4+7*([Week]-1))

Answer 2

Usted puede hacer esto un poco más simple. Si el año está en A2, p. número 2012, y la semana está en B2 se puede obtener la fecha de inicio de la semana con esta fórmula formato

=DATE(A2,1,-2)-WEEKDAY(DATE(A2,1,3))+B2*7

como la fecha

...... claramente se puede envolver que en un mes función para obtener el mes, es decir,

celda de resultado

=MONTH(DATE(A2,1,-2)-WEEKDAY(DATE(A2,1,3))+B2*7)

formato que en general

Explicación

Lo anterior considera que la fecha de la última lunes del año anterior y después se añade el número de semanas * 7 para dar la fecha de inicio de la semana en cuestión.

primer día del año para las semanas ISO es siempre el único lunes en el período del 29 de diciembre al 4 de enero, así que para encontrar esa fecha podemos encontrar el lunes inmediatamente antes del 5 de enero.

Para encontrar el Lunes inmediatamente antes de la fecha en que se puede utilizar esta fórmula genérica

=date-WEEKDAY(date-2)

por lo que si la fecha es el 5 de Ene del año se muestra en la A2 que es lo mismo que

=DATE(A2,1,5)-WEEKDAY(DATE(A2,1,3))

..... pero eso da el primer lunes de este año, así que si quiero el último lunes del año anterior puedo restar 7 - una forma de hacerlo es restar 7 de 5 para obtener -2 por lo tanto :

=DATE(A2,1,-2)-WEEKDAY(DATE(A2,1,3))

Answer 3

La Semana ISO siempre contienen 4 de enero, por lo que vamos a obtener su día de la semana a partir de Lunes (obviamente "año" es la celda con el año):

WEEKDAY(DATE(year;1;4)) 

Este es el número de días que necesitamos para volver a partir de esa fecha para encontrar un lunes (más uno)

DATE(year;1;4)-WEEKDAY(DATE(year;1;4))+1 

Así que ahora sólo tenemos que contar ...

DATE(year;1;4)-WEEKDAY(DATE(year;1;4))+1+weeknumber*7