Hendidura personalizada de Emacs

Question

Mi equipo usa un tipo especial de archivo para la configuración, y me gustaría auto-sangrar (bloquear sangría) el archivo usando emacs.

Me gustaría aumentar la sangría mediante un tamaño de tabulación para un paréntesis de apertura - {o [, y disminuir por un tamaño de tabulación para un paréntesis de cierre -} o].

Por ejemplo,

files = { 
    file1 = first_file.txt 
    file2 = second_file.txt 
    rules = { 
     skip_header = 1 
     fast_process = 1 
    } 
} 

indentación de estilo C no funciona ya que una línea no termina con semi-colon.

He estudiado la sangría de emacs durante medio día hoy, pero todavía no sé cómo hacer esto.

Answer 1

Me parece que javascript-mode haría lo correcto con su muestra. Puede que no sea perfecto, pero es mucho más fácil que escribir su propio modo de sangría.

Answer 2

Derive un nuevo modo del modo de texto o algo así y cree su propia función de sangría. Sé que es más fácil decirlo que hacerlo, por lo que este podría ser lo suficientemente cerca:

(define-derived-mode foo-mode text-mode "Foo" 
    "Mode for editing some kind of config files." 
    (make-local-variable 'foo-indent-offset) 
    (set (make-local-variable 'indent-line-function) 'foo-indent-line)) 

(defvar foo-indent-offset 4 
    "*Indentation offset for `foo-mode'.") 

(defun foo-indent-line() 
    "Indent current line for `foo-mode'." 
    (interactive) 
    (let ((indent-col 0)) 
    (save-excursion 
     (beginning-of-line) 
     (condition-case nil 
      (while t 
      (backward-up-list 1) 
      (when (looking-at "[[{]") 
       (setq indent-col (+ indent-col foo-indent-offset)))) 
     (error nil))) 
    (save-excursion 
     (back-to-indentation) 
     (when (and (looking-at "[]}]") (>= indent-col foo-indent-offset)) 
     (setq indent-col (- indent-col foo-indent-offset)))) 
    (indent-line-to indent-col))) 

abrir su archivo y hacer M-x foo-mode