Cómo analizar una cadena en un objeto DateTime en Perl?

Question

Conozco el módulo Perl DateTime, y muchos de los módulos DateTime::Format:: para analizar tipos específicos de formatos de fecha/hora. Sin embargo, dados algunos ejemplos de cadenas de fecha y hora, ¿cómo puedo averiguar (en el momento de la codificación/diseño, no en tiempo de ejecución) qué módulo específico debería usar?

Por ejemplo, quiero analizar cadenas como: October 28, 2011 9:00 PM PDT

¿Hay una lista en algún lugar de los formatos más comunes de fecha/hora en el que podía ver esto y encontrar lo que sería el módulo más adecuado?

También conozco algunos módulos que intentan "adivinar" el formato de cada cadena en tiempo de ejecución y hacen todo lo posible. Pero, para aplicaciones sensibles, me gustaría determinar (lo más estrictamente posible) el formato primero al diseñar una aplicación, y luego usar un módulo que me avisará si una cadena no coincide con el formato especificado.

¿Cómo debo hacer esto?

Answer 1

DateTime::Format::Strptime toma las cadenas de fecha/hora y los analiza en objetos DateTime.

#!/usr/bin/perl 

use strict; 
use warnings; 

use DateTime::Format::Strptime; 

my $parser = DateTime::Format::Strptime->new(
    pattern => '%B %d, %Y %I:%M %p %Z', 
    on_error => 'croak', 
); 

my $dt = $parser->parse_datetime('October 28, 2011 9:00 PM PDT'); 

print "$dt\n"; 

Las secuencias de caracteres utilizadas en el patrón son estándar POSIX. Vea 'man strftime' para más detalles.

Answer 2

Eche un vistazo al módulo Date::Parse, es decir, la función str2time(). Tiene soporte para la mayoría de los formatos comúnmente utilizados.

Ejemplo:

use Date::Parse; 
use DateTime; 

my $str = "Tue, 20 Sep 2011 08:51:08 -0500"; 
my $epoch = str2time($str); 
my $datetime = DateTime->from_epoch(epoch => $epoch); 

Answer 3

Tiendo a usar Time::Piece simplemente porque es parte del conjunto de módulos Perl estándar desde la versión 5.10.

No se puede superar su capacidad de parse date strings.

my $time = Time::Piece->strptime(
     "October 28, 2011 9:00 PM PDT", 
     "%B %d, %Y %r %Z"); 

Answer 4

Si está buscando fecha común formatos/hora echar un vistazo a DateTime::Locale

use DateTime::Locale 
my $locale = DateTime::Locale->load('DE_de'); 

The following methods return strings appropriate for the DateTime->format_cldr() method:

$locale->date_format_full() 
$locale->date_format_long() 
$locale->date_format_medium() 
$locale->date_format_short() 
$locale->date_format_default() 
$locale->time_format_full() 
$locale->time_format_long() 
$locale->time_format_medium() 
$locale->time_format_short() 
$locale->time_format_default() 
$locale->datetime_format_full() 
$locale->datetime_format_long() 
$locale->datetime_format_medium() 
$locale->datetime_format_short() 
$locale->datetime_format_default() 

puede analizar fechas con el módulo DateTime::Format::CLDR

use DateTime::Format::CLDR; 
# 1. Basic example 
my $cldr = DateTime::Format::CLDR->new(
    pattern  => 'dd.MM.yyyy HH:mm:ss', 
    locale  => 'de_DE', 
    time_zone => 'Europe/Berlin', 
); 
my $dt = $cldr->parse_datetime('26.06.2013 11:05:28');