¿Utiliza AWK para encontrar el número más pequeño y más grande en una columna?

Question

¡Si tengo un archivo con pocas columnas y quiero usar un comando AWK para mostrar el número más grande y el más bajo en una columna en particular!

ejemplo:

a 212 
b 323 
c 23 
d 45 
e 54 
f 102 

Quiero que mi comando para mostrar que el número más bajo es de 23 y otro comando para especificar el número más alto es de 323

no tengo ni idea de por qué las respuestas no están funcionando ! Pongo un ejemplo más realista de mi archivo (tal vez debería mencionar que se determina pestaña)

##FORMAT=<ID=DP,Number=1,Type=Integer,Description="# high-quality bases"> 
##FORMAT=<ID=SP,Number=1,Type=Integer,Description="Phred-scaled strand bias P-value"> 
##FORMAT=<ID=PL,Number=-1,Type=Integer,Description="List of Phred-scaled genotype likelihoods, number of values is (#ALT+1)*(#ALT+2)/2"> 
#CHROM POS  ID  REF  ALT  QUAL FILTER INFO FORMAT rmdup_wl_25248.bam 
Chr10 247  .  T  C  7.8  .  DP=37;AF1=0.5;CI95=0.5,0.5;DP4=7,1,19,0;MQ=15;FQ=6.38;PV4=0.3,1,0.038,1 GT:PL:GQ  0/1:37,0,34:36 
Chr10 447  .  A  C  75  .  DP=30;AF1=1;CI95=1,1;DP4=0,0,22,5;MQ=14;FQ=-108 GT:PL:GQ  1/1:108,81,0:99 
Chr10 449  .  G  C  35.2 .  DP=33;AF1=1;CI95=0.5,1;DP4=3,2,20,3;MQ=14;FQ=-44;PV4=0.21,1.7e-06,1,0.34  GT:PL:GQ  1/1:68,17,0:31 
Chr10 517  .  G  A  222  .  DP=197;AF1=1;CI95=1,1;DP4=0,0,128,62;MQ=24;FQ=-282  GT:PL:GQ  1/1:255,255,0:99 
Chr10 761  .  G  A  27  .  DP=185;AF1=0.5;CI95=0.5,0.5;DP4=24,71,8,54;MQ=20;FQ=30;PV4=0.07,8.4e-50,1,1  GT:PL:GQ  0/1:57,0,149:60 
Chr10 1829 .  A  G  3.01 .  DP=74;AF1=0.4998;CI95=0.5,0.5;DP4=18,0,54,0;MQ=19;FQ=4.68;PV4=1,9.1e-12,0.003,1 GT:PL:GQ  0/1:30,0,45:28 

debería decir que ya he añadir excluyendo línea que comienza con # por lo que este es el comando que utilizo:

awk '$1 !~/#/' | awk -F'\t' 'BEGIN{first=1;} {if (first) { max = min = $6; first = 0; next;} if (max < $6) max=$6; if (min > $6) min=$6; } END { print min, max }' wl_25210_filtered.vcf 

awk '$1 !~/#/' | awk -F'\t' 'BEGIN{getline;min=max=$6} NF{ max=(max>$6)?max:$6 min=(min>$6)?$6:min} END{print min,max}' wl_25210_filtered.vcf 

y

awk '$1 !~/#/' | awk -F'\t' ' 
NR==2{min=max=$6;next} 
NR>2 && NF{ 
    max=(max>$6)?max:$6 
    min=(min>$6)?$6:min 
} 
END{print min,max}' wl_25210_filtered.vcf 

Answer 1

Se pueden crear dos funciones definidas por el usuario y utilizarlos según su necesidad. Esto ofrecerá una solución más genérica.

[jaypal:~/Temp] cat file 
a 212 
b 323 
c 23 
d 45 
e 54 
f 102 
[jaypal:~/Temp] awk ' 
function max(x){i=0;for(val in x){if(i<=x[val]){i=x[val];}}return i;} 
function min(x){i=max(x);for(val in x){if(i>x[val]){i=x[val];}}return i;} 
{a[$2]=$2;next} 
END{minimum=min(a);maximum=max(a);print "Maximum = "maximum " and Minimum = "minimum}' file 
Maximum = 323 and Minimum = 23 

En la solución anterior, hay 2 definidos por el usuario funciones - max y min. Almacenamos la columna 2 en una matriz. Puede almacenar cada una de sus columnas de esta manera. En la instrucción END puede invocar la función y almacenar el valor en una variable e imprimirlo.

Espero que esto ayude!

Actualización:

ejecuta la siguiente de acuerdo con el último ejemplo -

[jaypal:~/Temp] awk ' 
function max(x){i=0;for(val in x){if(i<=x[val]){i=x[val];}}return i;} 
function min(x){i=max(x);for(val in x){if(i>x[val]){i=x[val];}}return i;} 
/^#/{next} 
{a[$6]=$6;next} 
END{minimum=min(a);maximum=max(a);print "Maximum = "maximum " and Minimum = "minimum}' sample 
Maximum = 222 and Minimum = 3.01 

Answer 2

awk 'BEGIN{first=1;} 
    {if (first) { max = min = $2; first = 0; next;} 
     if (max < $2) max=$2; if (min > $2) min=$2; } 
    END { print min, max }' file 

Answer 3

uso del BEGIN y END bloques para inicializar e imprimir variables que hacen un seguimiento de los mínimos y máximos.

por ejemplo,

awk 'BEGIN{max=0;min=512} { if (max < $1){ max = $1 }; if(min > $1){ min = $1 } } END{ print max, min}' 

Answer 4

Si el archivo contiene líneas vacías, ninguna de las soluciones publicadas va a funcionar. Para un manejo correcto de las líneas vacías probar esto:

$ cat f.awk 
BEGIN{getline;min=max=$6} 
NF{ 
    max=(max>$6)?max:$6 
    min=(min>$6)?$6:min 
} 
END{print min,max} 

A continuación, ejecute este comando:

sed "/^#/d" my_file | awk -f f.awk 

Al principio se llama la primera línea del archivo para establecer mínimos y máximos. Para cada línea no vacía, utilice la verificación de operador ternario, si se encontró un nuevo min o máximo. Al final, el resultado está impreso.

HTH Chris

Answer 5

awk 'BEGIN {max = 0} {if ($6>max) max=$6} END {print max}' yourfile.txt 

Answer 6

El min se puede encontrar por:

awk 'BEGIN {min=1000000; max=0;}; { if($2<min && $2 != "") min = $2; if($2>max && $2 != "") max = $2; } END {print min, max}' file 

Esta es la salida del mínimo y máximo, separados por comas