¿Cómo puedo obtener una lista de todos los archivos con una cierta extensión desde un directorio específico?

Question

Estoy usando este código para obtener una lista de todos los archivos en un directorio específico:

opendir DIR, $dir or die "cannot open dir $dir: $!"; 
my @files= readdir DIR; 
closedir DIR; 

¿Cómo puedo modificar el código o añadir algo a ella de modo que sólo busca los archivos de texto y sólo cargas la matriz con el prefijo del nombre de archivo?

contenidos de directorios de ejemplo: contenido de la matriz

. 
.. 
923847.txt 
98398523.txt 
198.txt 
deisi.jpg 
oisoifs.gif 
lksdjl.exe 

Ejemplo:

files[0]=923847 
files[1]=98398523 
files[2]=198 

Answer 1

my @files = glob "$dir/*.txt"; 
for (0..$#files){ 
    $files[$_] =~ s/\.txt$//; 
} 

Answer 2

que es suficiente para cambiar una línea:

my @files= map{s/\.[^.]+$//;$_}grep {/\.txt$/} readdir DIR; 

Answer 3

para conseguir el". txt "archivos, puede usar un archivo de prueba oper ator (-f: archivo regular) y una expresión regular.

my @files = grep { -f && /\.txt$/ } readdir $dir; 

De lo contrario, se puede buscar archivos de texto sólo, usando (operador de la prueba archivo de texto ASCII) -T de Perl

my @files = grep { -T } readdir $dir; 

Answer 4

Si puede utilizar las nuevas características de Perl 5.10, esta es la forma Yo lo escribiría

use strict; 
use warnings; 
use 5.10.1; 
use autodie; # don't need to check the output of opendir now 

my $dir = "."; 

{ 
    opendir my($dirhandle), $dir; 
    for(readdir $dirhandle){ # sets $_ 
    when(-d $_){ next } # skip directories 
    when(/^[.]/){ next } # skip dot-files 

    when(/(.+)[.]txt$/){ say "text file: ", $1 } 
    default{ 
     say "other file: ", $_; 
    } 
    } 
    # $dirhandle is automatically closed here 
} 

O si tiene directorios muy grandes, se puede utilizar un bucle while.

{ 
    opendir my($dirhandle), $dir; 
    while(my $elem = readdir $dirhandle){ 
    given($elem){ # sets $_ 
     when(-d $_){ next } # skip directories 
     when(/^[.]/){ next } # skip dot-files 

     when(/(.+)[.]txt$/){ say "text file: ", $1 } 
     default{ 
     say "other file: ", $_; 
     } 
    } 
    } 
} 

Answer 5

Sólo tiene que utilizar esto:

my @files = map {-f && s{\.txt\z}{} ? $_ :()} readdir DIR; 

Answer 6

Ésta es la forma más sencilla que he encontrado (como en el ser humano legible) utilizando la función glob:

# Store only TXT-files in the @files array using glob 
my @files = grep (-f ,<*.txt>); 
# Write them out 
foreach $file (@files) { 
    print "$file\n"; 
} 

Además, el "-f "asegura que solo los archivos reales (y no los directorios) se almacenen en la matriz.