En clojure, ¿cómo puedo evaluar los argumentos a una macro desde otra macro?

Question

Tengo dos macros. El primero toma un símbolo como el único parámetro (porque se pasa a def, que necesita un símbolo). La segunda función toma una lista de símbolos y debe llamar a la primera con cada símbolo individualmente.

(defmacro m1 [s] 
    '(let [f# ... dynamic function definition ...] 
     (def ~s f#)) 

La segunda macro debe tener una lista de símbolos y pasarlos a la primera, pero no puedo hacer que funcione. Lo mejor que podía venir fue el siguiente:

(defmacro m2 [symbols] 
    `(for [s# ~symbols] (eval (read-string (str "(name.of.current.namespace/m1 " s# ")"))))) 

que obliga al s# a ser evaluados antes de pasar a la primera macro. También se invoca con una lista de cadenas, en lugar de una lista de símbolos.

Esto es útil para una biblioteca que estoy usando para la cual todas las funciones en la biblioteca toman los mismos dos primeros parámetros. Estoy intentando crear funciones de envoltura, en mi espacio de nombres, para algunas de las funciones, que proporciona automáticamente los primeros dos valores de parámetros que son comunes a todos ellos.

¿Alguna idea para mejorar esto?

Answer 1

Normalmente, cuando se pregunta cómo conseguir que cooperen dos macros, la respuesta es no convertirlas en ambas macros. Creo que mi entrada de blog en macro-writing macros me ayudará a aclarar. Por esta situación particular probablemente me combino dos sugerencias de los comentarios:

(defmacro build-simpler-functions [& names] 
    (cons 'do 
     (for [name names] 
      `(def ~(symbol (str "simple-" name)) 
      (partial ~name 5 10))))) ; if you always pass 5 and 10 

(build-simpler-functions f1 f2) 

Esto expande a

(do 
    (def simple-f1 (clojure.core/partial f1 5 10)) 
    (def simple-f2 (clojure.core/partial f2 5 10))) 

que se parece básicamente lo que quiere.

Editar: si los argumentos que pasas "siempre" son diferentes para cada función, usted puede hacer esto:

(defmacro build-simpler-functions [& names] 
    (cons 'do 
     (for [[name & args] names] 
      `(def ~(symbol (str "simple-" name)) 
      (partial ~name ~@args))))) 

(build-simpler-functions [f1 5 10] [f2 "Yo dawg"]) ; expansion similar to the previous