Delphi - Dibujar texto multilínea en el centro de una rect

Question

En Delphi deseo dibujar texto dentro de un TRect. Estoy esperando para la siguiente funcionalidad:

1. dibujar el texto centrado verticalmente dentro de la TRect
2. Dibujar el texto centrado horizontalmente dentro del TRect
3. Si no hay espacio para más de 1 línea de texto (usando TRect de altura), dibuje el texto multilínea
4. Si el texto no cabe en el TRect (ya sea en una línea individual o múltiple), a continuación, agregue puntos suspensivos al texto.

puedo ver la función Windows.DrawText() casi cubre esta funcionalidad, sin embargo, cuando la escritura de texto, multilínea y centrada verticalmente son mutuamente excluyentes.

Me preguntaba si esta funcionalidad está integrada en Windows (2000+)? Si no, ¿hay alguna manera de hacerlo sin escribir mi propia función?

Answer 1

Disculpa, esto es una combinación de todas las respuestas y los comentarios anteriores. Pero parece que OP necesita más ayuda.

function DrawTextCentered(Canvas: TCanvas; const R: TRect; S: String): Integer; 
var 
    DrawRect: TRect; 
    DrawFlags: Cardinal; 
    DrawParams: TDrawTextParams; 
begin 
    DrawRect := R; 
    DrawFlags := DT_END_ELLIPSIS or DT_NOPREFIX or DT_WORDBREAK or 
    DT_EDITCONTROL or DT_CENTER; 
    DrawText(Canvas.Handle, PChar(S), -1, DrawRect, DrawFlags or DT_CALCRECT); 
    DrawRect.Right := R.Right; 
    if DrawRect.Bottom < R.Bottom then 
    OffsetRect(DrawRect, 0, (R.Bottom - DrawRect.Bottom) div 2) 
    else 
    DrawRect.Bottom := R.Bottom; 
    ZeroMemory(@DrawParams, SizeOf(DrawParams)); 
    DrawParams.cbSize := SizeOf(DrawParams); 
    DrawTextEx(Canvas.Handle, PChar(S), -1, DrawRect, DrawFlags, @DrawParams); 
    Result := DrawParams.uiLengthDrawn; 
end; 

procedure TForm1.FormPaint(Sender: TObject); 
const 
    S = 'This is a very long text as test case for my paint routine.'; 
var 
    R: TRect; 
begin 
    SetRect(R, 100, 100, 200, 140); 
    Canvas.Rectangle(R); 
    InflateRect(R, -1, -1); 
    Caption := Format('%d characters drawn', [DrawTextCentered(Canvas, R, S)]); 
end; 

Answer 2

Mida primero el texto con DT_CALCRECT. Pase DT_WORDBREAK para especificar que el ajuste de palabras esté habilitado. Esto le permitirá encontrar la altura requerida para su texto. Luego puede, en su código, calcular el desplazamiento vertical que le da texto centrado verticalmente, y dibujar a ese desplazamiento.