Mensajes personalizados en clases sin ventana: ¿necesita un controlador predeterminado?

Question

Con una clase (TObject) Tengo:

private 
    FHwnd : HWND; 
    procedure HandleMyMessage(var Message : TMessage); message TH_MYMESSAGE; 

donde TH_MYMESSAGE = WM_USER + 1

En el constructor de la clase:

FHwnd := AllocateHWND(HandleMyMessage); 

El único objeto que recibe una referencia a FHwnd es una costumbre privada TThread (creado dentro de esta clase) y el único mensaje que publica es TH_MYMESSAGE. Entiendo que la directiva message en la declaración de procedimiento restringe su manejo a solo TH_MYMESSAGE.

Esto funcionaba bien en las pruebas, pero después de la integración en una aplicación mucho más grande recibo retroalimentación que HandleMyMessage está disparando también para otros mensajes (con resultados obvios no deseados).

Esto se corrigió fácilmente agregando if Message.Msg <> TH_MYMESSAGE then Exit; en HandleMyMessage. Mi pregunta es: ¿por qué está pasando esto?

Mi mejor conjetura es que AllocateHWND ha hecho HandleMyMessage el equivalente de un DefWndProc a pesar de tener la directiva message. ¿Hay una forma correcta de implementar esto que me falta?

Answer 1

Bueno, sí, por supuesto. AllocateHWnd acepta TWndMethod para actuar como el procedimiento de ventana de la ventana creada. La confusión, creo, es causada por que el compilador acepta la directiva messsage. No lo ponga:

private 
    FHwnd : HWND; 
    procedure HandleMyMessage(var Message : TMessage); 

.. 

procedure TMyClass.HandleMyMessage(var Message: TMessage); 
begin 
    case Message.Msg of 
    TH_MYMESSAGE: // 
    end; 
    Message.Result := DefWindowProc(FHWnd, Message.Msg, Message.WParam, Message.LParam); 
end; 

---

edición: (respuesta al comentario). Para que el mensaje se maneja en la clase que creó la ventana de utilidad, puede dirigir su mensaje desde la ventana AllocateHWnd crea a su clase:

private 
    FHwnd : HWND; 
    procedure HandleMyMessage(var Message : TMessage); 
    procedure THMyMessage(var Message: TMessage); message TH_MYMESSAGE; 

.. 

procedure TMyClass.HandleMyMessage(var Message: TMessage); 
begin 
    case Message.Msg of 
    TH_MYMESSAGE: Dispatch(Message); 
    end; 
    Message.Result := DefWindowProc(FHWnd, Message.Msg, Message.WParam, Message.LParam); 
end; 

procedure TMyClass.THMyMessage(var Message: TMessage); 
begin 
    // 
end;