Usar Clojure para probar la unidad Java

Question

Una de las formas de lograr que una organización acepte un lenguaje JVM alternativo es usarlo primero para probar el código Java de la unidad: "Jefe, voy a escribir algunas pruebas unitarias en XXX. Nunca saldrá a producción ".

¿Hay algún tutorial para hacer esto en Clojure?

Acabo de comenzar a usar Scala para hacer esto para probar un servidor REST de Java. Escribir las pruebas en Scala me permite incrustar la salida XML esperada, simular las llamadas a la base de datos con objetos literales List, etc., sin mencionar que los rasgos hacen que sea muy fácil abstraer el código común para las pruebas.

Answer 1

Básicamente lo que necesita es clojure.test (o una de las muchas otras librerías de prueba de clojure) y Clojure estándar Java interop.

Ejemplo:

(ns example.test-java-util 
    (:use 
    [clojure.test]) 
    (:import [java.util HashSet])) 

(defn new-empty-set [] 
    (HashSet.)) 

(deftest test-empty-set 
    (is (= 0 (.size (new-empty-set)))) 
    (is (= true (.isEmpty (new-empty-set)))) 
    (is (= (new-empty-set) (new-empty-set)))) 

(deftest test-add-remove 
    (is (= (new-empty-set) 
     (doto (new-empty-set) 
      (.add "xyz") 
      (.remove "xyz"))))) 

Y luego se ejecutaría en una variedad de maneras. Las herramientas de compilación como Maven usando el plugin maven clojure las ejecutan automáticamente como parte de la "prueba mvn". En una repl, se puede hacer algo como:

example.test-java-util> (run-tests 'example.test-java-util) 

Testing example.test-java-util 

Ran 1 tests containing 4 assertions. 
0 failures, 0 errors. 
{:type :summary, :test 1, :pass 4, :fail 0, :error 0} 

Answer 2

Aquí hay un ejemplo usando Leiningen, test.check y asumiendo una disposición estándar Maven:

pom.xml 
project.clj 
src 
    main 
    java 
     quicktest 
     Discontinuities.java 
    test 
    clojure 
     quicktest 
     test_discontinuities.clj 

La función de Java para probar:

package quicktest; 
public class Discontinuities { 
    public static double f5(double x) { 
     return x/(x-5); 
    } 
} 

El caso de prueba Clojure:

(ns quicktest.test-discontinuities 
    (:import [quicktest Discontinuities]) 
    (:require [clojure.test :refer :all] 
    [clojure.test.check :as tc] 
    [clojure.test.check.generators :as gen] 
    [clojure.test.check.properties :as prop] 
    [clojure.test.check.clojure-test :as ct :refer (defspec)])) 

(deftest test-single-case 
    (is (= 2.0 (Discontinuities/f5 10)))) 

(defspec test-discontinuities 1e4 
     (prop/for-all [x gen/nat ] 
         (let [y (Discontinuities/f5 x)] 
          (is (<= y x))))) 

El proyecto:

(defproject quicktest/discontinuities "0.1" 
      :dependencies [[org.clojure/clojure "1.8.0"] 
          [org.clojure/test.check "0.9.0"]] 
      :java-source-paths ["src/main/java"] 
      :test-paths ["src/test/clojure"]) 

El pom:

<?xml version="1.0" encoding="UTF-8"?> 
<project xmlns="http://maven.apache.org/POM/4.0.0" 
     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
     xsi:schemaLocation="http://maven.apache.org/POM/4.0.0 http://maven.apache.org/xsd/maven-4.0.0.xsd"> 
    <modelVersion>4.0.0</modelVersion> 
    <groupId>quicktest</groupId> 
    <artifactId>discontinuities</artifactId> 
    <version>0.1</version> 
</project> 

Ejecutar con:

mvn compile 
lein deps 
lein test 

Resultados

La falla en la función se encontró rápidamente:

FAIL in (test-discontinuities) (test_discontinuities.clj:13) 
expected: (<= y x) 
actual: (not (<= Infinity 5)) 
{:test-var "test-discontinuities", 
:result false, 
:seed 1431128331945, 
:failing-size 23, 
:num-tests 24, 
:fail [5], 
:shrunk {:total-nodes-visited 3, :depth 0, :result false, :smallest [5]}}