Usando Perl para renombrar archivos en un directorio

Question

Me gustaría tomar un directorio y para todos los archivos de correo electrónico (* .msg), elimine la 'RE' al comienzo. Tengo el siguiente código pero el cambio de nombre falla.

opendir(DIR, 'emails') or die "Cannot open directory"; 
@files = readdir(DIR); 
closedir(DIR); 

for (@files){ 
    next if $_ !~ m/^RE .+msg$/; 
    $old = $_; 
    s/RE //; 
    rename($old, $_) or print "Error renaming: $old\n"; 
} 

Answer 1

Si el directorio de ./emails contiene estos archivos:

1.msg 
2.msg 
3.msg 

entonces su @files quedará del siguiente modo ('.', '..', '1.msg', '2.msg', '3.msg') pero su rename quiere nombres como 'emails/1.msg', 'emails/2.msg', etc. Por lo que puede cambiar el nombre de chdir antes:

chdir('emails'); 
for (@files) { 
    #... 
} 

Es probable que desee ch compruebe el valor de retorno chdir también.

o añadir los nombres de directorio usted mismo:

rename('emails/' . $old, 'emails/' . $_) or print "Error renaming $old: $!\n"; 
# or rename("emails/$old", "emails/$_") if you like string interpolation 
# or you could use map if you like map 

Es posible que desee combinar su lectura directorio y filtrado usando grep:

my @files = grep { /^RE .+msg$/ } readdir(DIR); 

o incluso esto:

opendir(DIR, 'emails') or die "Cannot open directory"; 
for (grep { /^RE .+msg$/ } readdir(DIR)) { 
    (my $new = $_) =~ s/^RE //; 
    rename("emails/$_", "emails/$new") or print "Error renaming $_ to $new: $!\n"; 
} 
closedir(DIR); 

Answer 2

Usted parece estar asumiendo glob -como el comportamiento en lugar de readdir -comportamiento similar.

La llamada al sistema subyacente readdir devuelve solo los nombres de archivo dentro del directorio, e incluirá dos entradas . y ... Esto lleva a la función readdir en Perl, solo para dar un poco más de detalle en la respuesta de mu.

Alternativamente, no tiene mucho sentido usar readdir si está recopilando todos los resultados en una matriz de todos modos.

@files = glob('emails/*'); 

Answer 3

Como ya se mencionó, su secuencia de comandos falla debido a la ruta que espera y los usos de la secuencia de comandos no son los mismos.

Sugiero un uso más transparente. Hardcoding un directorio no es una buena idea, IMO. Como supe un día cuando hice un script para alterar algunos archivos originales, con el camino codificado, y un colega mío pensó que sería un buen script para tomar prestado para alterar sus copias. Ooops!

Uso:

perl script.pl "^RE " *.msg 

es decir expresiones regulares, a continuación, una lista de archivos glob, en que la trayectoria se denota en relación con la secuencia de comandos, por ejemplo *.msg, emails/*.msg o incluso /home/pat/emails/*.msg /home/foo/*.msg. (múltiples globs posibles)

El uso de las rutas absolutas dejará al usuario sin ninguna duda en cuanto a qué archivos afectará, y también hará que la secuencia de comandos sea reutilizable.

Código:

use strict; 
use warnings; 
use v5.10; 
use File::Copy qw(move); 

my $rx = shift; # e.g. "^RE " 

if ($ENV{OS} =~ /^Windows/) { # Patch for Windows' lack of shell globbing 
    @ARGV = map glob, @ARGV; 
} 

for (@ARGV) { 
    if (/$rx/) { 
     my $new = s/$rx//r; # Using non-destructive substitution 
     say "Moving $_ to $new ..."; 
     move($_, $new) or die $!; 
    } 
}