LINQ no lo hace el grupo en VB.Net

Question

Para los fines educativos que trataron de convertir la siguiente expresión LINQ del libro "Linq en acción" en VB.net

C# original

var list = 
    from book in SampleData.Books 
    group book by new { book.Publisher.Name, book.Subject } 
    into grouping 
    select new { 
    Publisher = grouping.Key.Publisher, 
    Subject = grouping.Key.Subject, 
    Book = grouping 
    }; 

Mi intento:

Dim list = _books.GroupBy(Function(book) New With {.Publisher = book.Publisher.Name, 
                book.Subject}). 
        Select(Function(grouping) New With {.Publisher = grouping.Key.Publisher, 
                 .Subject = grouping.Key.Subject, 
                 .Books = grouping}) 

For Each item In list 
    Console.WriteLine("Publisher:" & item.Publisher & ", Subject:" & item.Subject) 
    For Each Book In item.Books 
    Console.WriteLine(" " & Book.Title) 
    Next 
Next 

Esto lleva a la siguiente salida:

Publisher:FunBooks, Subject:Fun 
    Funny Stories 
Publisher:Joe Publishing, Subject:Work 
    LINQ rules 
Publisher:Joe Publishing, Subject:Work 
    C# on rails 
Publisher:Joe Publishing, Subject:Fun 
    All your base are belong to us 
Publisher:FunBooks, Subject:Fun 
    Bonjour mon Amour 

Espero que los libros "LINQ rules" y "C# on rails" estén agrupados, así como los libros "Funny Stories" y "Bonjour mon Amour" porque tienen el mismo Publisher and Subject. Mi clave anónima consiste en un nuevo objeto de dos cadenas simples.

Ya he intentado buscar en SO, pero other (or) las respuestas no resuelven mi problema. Incluso algunos traductores de código como telerik o carlosag no son de ayuda en este caso.

Answer 1

Este es el problema:

GroupBy(Function(book) New With {.Publisher = book.Publisher.Name, 
            book.Subject}) 

Eso no es equivalente a la versión C#, porque por desgracia VB utiliza mutables propiedades en los tipos anónimos por defecto, y las propiedades mutables no se considera como parte del hash operaciones de código o igualdad. Necesita hacer que ambas propiedades propiedades "Clave":

GroupBy(Function(book) New With {Key .Publisher = book.Publisher.Name, 
           Key book.Subject}) 

Entonces debería funcionar bien. Puede leer más acerca de los tipos anónimos en VB on MSDN.

Answer 2

Si bien aplaudo sus esfuerzos para traducir las muestras, en realidad tenemos todas las muestras para LINQ in Action en C# y VB disponibles para su descarga desde el sitio de Manning: http://www.manning.com/marguerie/. Además, hemos agregado muestras a las muestras de LinqPad para que sea más fácil probar las muestras y guardar sus cambios. Consulte http://www.thinqlinq.com/Default/LINQ-In-Action-Samples-available-in-LINQPad.aspx para obtener instrucciones sobre cómo acceder a eso.

Parece que está trabajando en el ejemplo 5.06b. Actualizándolo poco, nuestra traducción VB es:

Dim query = _ 
    From book In SampleData.Books _ 
    Group book.Title By book.Publisher, book.Subject Into grouping = Group _ 
    Select _ 
    Publisher = Publisher.Name, _ 
    Subject = Subject.Name, _ 
    Titles = grouping 

Si desea utilizar la sintaxis lambda, que es necesario especificar la clave como @johnskeet informativo:

Dim list = SampleData.Books.GroupBy(Function(book) New With { 
          Key .Publisher = book.Publisher.Name, 
          Key .Subject = book.Subject}). 
       Select(Function(grouping) New With { 
        .Publisher = grouping.Key.Publisher, 
        .Subject = grouping.Key.Subject, 
        .Books = grouping})