SPARQL: Obtenga todas las entidades de subclases de una cierta clase

Question

Tengo que obtener todas las instancias de una clase C y subclases (directas o indirectas) de C, en SPARQL.

yo puede conseguir todas las subclases directas de C de esta manera:

SELECT ?entity 
WHERE { 
    ?subclass rdfs:subClassOf :C . 
    ?entity rdf:type ?subclass . 
} 

pero no puedo obtener las instancias de una subclase indirecta y tampoco ninguna instancia de C.

Como sé (He precalculado) todas las subclases (directas e indirectas de C), y puedo construir una consulta dinámica, ¿es posible crear una consulta como la siguiente?

SELECT ?entity 
WHERE { 
    ?entity rdf:type in <list>. 
} 

Gracias a todos.

EDIT:

acabo lo resolvió, aunque de manera no elegante.

SELECT ?entity 
WHERE { 
    { ?entity rdf:type :C } 
    UNION { ?entity rdf:type :SubClass1 } 
    UNION { ?entity rdf:type :SubClass2 } 
    UNION { ?entity rdf:type :SubClass3 } 
} 

Answer 1

Una mejor solución es utilizar expresiones de ruta característica en SPARQL 1.1

Esto puede reescribir como:

SELECT ?entity 
WHERE { 
    ?entity rdf:type ?type. 
    ?type rdfs:subClassOf* :C. 
} 

Answer 2

Sobre la base de la SPARQL 1.1 specification la forma correcta de hacerlo sería:

SELECT ?entity 
WHERE { 
    ?entity rdf:type/rdfs:subClassOf* :C 
} 

Sin soporte para rutas de propiedad no hay forma de expre Ssing jerarquías de clase de longitud arbitraria.