Cómo Async.AwaitTask en Tarea simple (no Tarea <T>)?

Question

Estoy tratando de consumir una biblioteca C# en F #. La biblioteca hace un uso intensivo de async/await. Quiero usar dentro de un flujo de trabajo async { ... } en F #.

veo podemos Async.AwaitTask en métodos asíncrono C# regresan Task<T>, pero ¿qué pasa con los que regresan llanura Task?

Tal vez, ¿hay un ayudante para convertir estos a Async<unit> o para convertir a TaskTask<unit> por lo que trabajará con Async.AwaitTask?

Answer 1

Puede utilizar ContinueWith:

let awaitTask (t: Task) = t.ContinueWith (fun t ->()) |> Async.AwaitTask 

O AwaitIAsyncResult con tiempo de espera infinito:

let awaitTask (t: Task) = t |> Async.AwaitIAsyncResult |> Async.Ignore 

Answer 2

Me gustó mucho la sugerencia de Ashley usando la composición de funciones. Además, se puede ampliar el módulo asíncrono como esto:

module Async = 
    let AwaitTaskVoid : (Task -> Async<unit>) = 
     Async.AwaitIAsyncResult >> Async.Ignore 

Entonces aparece en Intellisense junto con Async.AwaitTask. Se puede usar así:

do! Task.Delay delay |> Async.AwaitTaskVoid 

¿Alguna sugerencia para un nombre mejor?

Answer 3

Actualización:

La biblioteca FSharp.Core para F # 4.0 ahora incluye una sobrecarga Async.AwaitTask que acepte una llanura Task. Si está usando F # 4.0, entonces debe usar esta función central en lugar del siguiente código.

---

Respuesta original:

Si su tarea podría lanzar una excepción, entonces probablemente también quieren comprobar esto. p.ej.

let awaitTask (task : Task) = 
    async { 
     do! task |> Async.AwaitIAsyncResult |> Async.Ignore 
     if task.IsFaulted then raise task.Exception 
     return() 
    } 

Answer 4

se propaguen correctamente ambas excepciones y cancelación de forma adecuada, lo que se necesita algo como esto (basado parcialmente en respuesta borrado Tomáš Petříček):

module Async = 
    let AwaitVoidTask (task : Task) : Async<unit> = 
     Async.FromContinuations(fun (cont, econt, ccont) -> 
      task.ContinueWith(fun task -> 
       if task.IsFaulted then econt task.Exception 
       elif task.IsCanceled then ccont (OperationCanceledException()) 
       else cont()) |> ignore)