Incluyendo archivos de recursos en el directorio de compilación de Qt Creator

Question

Tengo un proyecto en el que estoy trabajando con Qt Creator y estoy intentando que agregue mis archivos de recursos a mis directorios de compilación (salida) automáticamente. Tengo los archivos en el directorio del proyecto, pero no sé cómo editar el archivo * .pro para que incluya archivos de contenido adicionales. (¿Si eso es posible?)

¿Alguien sabe cómo obtener los archivos de contenido exactamente como están en mis directorios de salida?

EDIT:

Sólo para que todo el mundo sabe exactamente lo que estoy tratando de hacer ... Quiero copiar automáticamente FFmpeg como un ejecutable en mis directorios de construcción. De esta forma, si el resultado de compilación no existe, se copiará justo antes de que se depure la aplicación.

Estoy tratando de evitar que las operaciones limpias eliminen los recursos y que tenga que copiarlos una y otra vez. Además ... Trabajo en varias computadoras y uso SVN o Dropbox, por lo que quiero mantener mis rutas relativas. Cambiarán cuando me mueva de una computadora a otra.

respuesta final:

CONFIG(release, debug|release) { 
    DESTDIR = release 
} else { 
    DESTDIR = debug 
} 

#for Windows 
win32 { 
    #in Windows, you can use & to separate commands 
    copyfiles.commands += @echo NOW COPYING ADDITIONAL FILE(S) & 
    copyfiles.commands += @call copy ..\\$${TARGET}\\ffmpeg.exe $${DESTDIR}\\ffmpeg.exe 
} 

#for Mac 
macx { 
    #commands would go here if I had them 
} 

QMAKE_EXTRA_TARGETS += copyfiles 
POST_TARGETDEPS += copyfiles 

Answer 1

Si desea copiar automáticamente los archivos en un directorio después de la construcción se puede utilizar una meta posterior construcción.

En el archivo de pro:

win32 { 
    copyfiles.commands = @call copy <from> <to> 
} 
macx { 
    copyfiles.commands = cp <from> <to> 
} 
QMAKE_EXTRA_TARGETS += copyfiles 
POST_TARGETDEPS += copyfiles 

En lugar de copy <from> <to> es obvio que puede llamar a un archivo/batch script que hace más después construir pasos.

Answer 2

Echa un vistazo a Qt Resource System.

Para añadir el archivo de recursos en su proyecto, usted tiene añadir lo siguiente en su archivo .pro ..

RESOURCES = application.qrc

Ejemplos detallados disponibles en el Qt Docs ..

Una vez añadido en el Pro File, se agregará un archivo separado .qrc en su proyecto Qt con el que puede hacer doble clic y agregar los recursos deseados, como iconos, archivos de traducción, etc.,

Espero que ayude ..

Answer 3

Ahora es 2012, y ninguno de estos métodos funciona para mí. Me sale este error:

mingw32-make[1]: Leaving directory `C:/src/GL-Texture-build-desktop-Qt_in_PATH_Debug' 
/usr/bin/sh: copy: command not found 
mingw32-make[1]: *** [copyfiles] Error 127 
mingw32-make: *** [debug] Error 2 
00:28:19: The process "C:\QtSDK\mingw\bin\mingw32-make.exe" exited with code 2. 
Error while building/deploying project GL-Texture (target: Desktop) 
When executing step 'Make' 

Mirando el mensaje, me sorprende ver que está utilizando el shell sh, probablemente a causa de MinGW. De todos modos he resuelto este problema utilizando el equivalente Unix:

CONFIG(release, debug|release) { 
    DESTDIR = release 
} else { 
    DESTDIR = debug 
} 

#for Windows 
win32 { 
    copyfiles.commands += @echo NOW COPYING ADDITIONAL FILES & 
    copyfiles.commands += cp -r ../$${TARGET}/textures $${DESTDIR}/ 
} 

QMAKE_EXTRA_TARGETS += copyfiles 
POST_TARGETDEPS += copyfiles 

Esto sucede en Windows 7/QT 4.6.3.