¿Por qué este método de extensión arroja una NullReferenceException en VB.NET?

Question

Por experiencia anterior, tenía la impresión de que es perfectamente legal (aunque quizás no aconsejable) llamar a los métodos de extensión en una instancia nula. Así que en C#, este código se compila y se ejecuta:

// code in static class 
static bool IsNull(this object obj) { 
    return obj == null; 
} 

// code elsewhere 
object x = null; 
bool exists = !x.IsNull(); 

Sin embargo, sólo estaba preparando una pequeña suite de código de ejemplo para los demás miembros de mi equipo de desarrollo (que sólo pasaron a .NET 3.5 y no tengo se le ha asignado la tarea de poner al equipo al día sobre algunas de las nuevas funciones disponibles para nosotros), y escribí lo que pensó que era el equivalente de VB.NET del código anterior, solo para descubrir que en realidad arroja un NullReferenceException . El código que escribí fue el siguiente:

' code in module ' 
<Extension()> _ 
Function IsNull(ByVal obj As Object) As Boolean 
    Return obj Is Nothing 
End Function 

' code elsewhere ' 
Dim exampleObject As Object = Nothing 
Dim exists As Boolean = Not exampleObject.IsNull() 

El depurador se detiene justo allí, como si hubiera llamado a un método de instancia. ¿Estoy haciendo algo mal (por ejemplo, hay alguna diferencia sutil en la forma en que definí el método de extensión entre C# y VB.NET)? ¿Es realmente no legal llamar a un método de extensión en una instancia nula en VB.NET, aunque es legal en C#? (Hubiera pensado que esto era algo de .NET en lugar de algo específico del idioma, pero quizás estaba equivocado.)

¿Alguien me puede explicar esto?

Answer 1

No se puede extender el tipo de objeto en VB.NET.

Principalmente, no permitimos que los métodos de extensión que ser cancelado de cualquier expresión que se escribe de forma estática como "objeto". Esto fue necesario para evitar que los códigos de extensión destruyan cualquier código de límite tardío existente que haya escrito.

Referencia:

• http://blogs.msdn.com/vbteam/archive/2007/01/24/extension-methods-and-late-binding-extension-methods-part-4.aspx

• http://johnwest.spaces.live.com/Blog/cns!EBA860160D5F5D75!463.entry

Answer 2

Parece que el problema es que el objeto es nulo. Además, si intenta algo como lo siguiente, obtendrá una excepción diciendo esa cadena no tiene un método de extensión llamado EsNulo

Dim exampleObject As Object = "Test" 
Dim text As String = exampleObject.IsNull() 

Creo que cualquier valor que está poniendo en exampleObject, el marco sabe qué tipo es. Yo personalmente evitaría métodos extensiones en la clase Object, no sólo en VB, sino también en CSharp

Answer 3

Actualización:

La respuesta a continuación parece ser específica para el caso se prolonga el System.Object. Al extender otras clases, no hay NullReferenceException en VB.

Este comportamiento es por diseño por la razón indicada en este Connect issue:

VB le permite llamar a los métodos de extensión definidos el objeto, pero sólo si la variable no es estática escrito como objeto.

La razón es VB también es compatible con enlace tardío, y si se unen a un método extensión cuando se realiza una llamada fuera una variable declarada como objeto, entonces es ambigua o no que está tratando de llamar un método de extensión o un método de enlace posterior diferente con el mismo nombre.

Teóricamente podría permitir esto con Strict On, pero uno de los principios de Option Strict es que no debe cambiar la semántica de su código. Si esto está permitido, entonces cambiando la configuración de Opción estricta podría causar un reenlace silencioso a un método diferente , resultando en total comportamiento de tiempo de ejecución diferente.

Ejemplo:

Imports System.Runtime.CompilerServices 

Module Extensions 
    <Extension()> _ 
    Public Function IsNull(ByVal obj As Object) As Boolean 
     Return obj Is Nothing 
    End Function 

    <Extension()> _ 
    Public Function IsNull(ByVal obj As A) As Boolean 
     Return obj Is Nothing 
    End Function 

    <Extension()> _ 
    Public Function IsNull(ByVal obj As String) As Boolean 
     Return obj Is Nothing 
    End Function 

End Module 

Class A 
End Class 

Module Module1 

    Sub Main() 
     ' works 
     Dim someString As String = Nothing 
     Dim isStringNull As Boolean = someString.IsNull() 

     ' works 
     Dim someA As A = Nothing 
     Dim isANull As Boolean = someA.IsNull() 

     Dim someObject As Object = Nothing 
     ' throws NullReferenceException 
     'Dim someObjectIsNull As Boolean = someObject.IsNull() 

     Dim anotherObject As Object = New Object 
     ' throws MissingMemberException 
     Dim anotherObjectIsNull As Boolean = anotherObject.IsNull() 
    End Sub 

End Module 

De hecho, el compilador de VB crea una llamada de unión tarde en caso de que su variable es de tipo estático como Object:

.locals init ([0] object exampleObject, [1] bool exists) 
    IL_0000: ldnull 
    IL_0001: stloc.0 
    IL_0002: ldloc.0 
    IL_0003: ldnull 
    IL_0004: ldstr  "IsNull" 
    IL_0009: ldc.i4.0 
    IL_000a: newarr  [mscorlib]System.Object 
    IL_000f: ldnull 
    IL_0010: ldnull 
    IL_0011: ldnull 
    IL_0012: call  
    object [Microsoft.VisualBasic]Microsoft.VisualBasic. 
     CompilerServices.NewLateBinding::LateGet(
     object, 
     class [mscorlib]System.Type, 
     string, 
     object[], 
     string[], 
     class [mscorlib]System.Type[], 
     bool[]) 
    IL_0017: call  object [Microsoft.VisualBasic]Microsoft.VisualBasic.CompilerServices.Operators::NotObject(object) 
    IL_001c: call  bool [Microsoft.VisualBasic]Microsoft.VisualBasic.CompilerServices.Conversions::ToBoolean(object) 
    IL_0021: stloc.1 

Answer 4

parece ser algo peculiar con Objeto, posiblemente un error en VB o una limitación en el compilador, ¡podría necesitar a su Santidad Jon Skeet para comentar!

Básicamente parece estar intentando enlazar tarde la llamada IsNull en tiempo de ejecución, en lugar de llamar al método de extensión, que causa la NullReferenceException. Si activa Option Strict, verá esto en el momento del diseño con los garabatos rojos.

Cambio de exampleObject a algo que no sea Object en sí mismo permitirá que su código de ejemplo funcione, incluso si el valor de dicho tipo es Nothing.