duplicados en una secuencia

Question

Lo mejor que podía venir fue:

(defn dups [seq] 
    (map (fn [[id freq]] id) 
     (filter (fn [[id freq]] (> freq 1)) 
       (frequencies seq)))) 

¿Hay una manera más concisa?

Answer 1

utilizar una lista de comprensión:

(defn dups [seq] 
    (for [[id freq] (frequencies seq) ;; get the frequencies, destructure 
     :when (> freq 1)]   ;; this is the filter condition 
    id))        ;; just need the id, not the frequency 

Answer 2

(map key (remove (comp #{1} val) 
       (frequencies seq))) 

Answer 3

Si desea encontrar duplicados con sede fuera alguna propiedad de los elementos de la lista (es decir, se trata de una lista de los mapas o una lista de registros/objetos Java)

(defn dups-with-function 
    [seq f] 
    (->> seq 
     (group-by f) 
     ; filter out map entries where its value has only 1 item 
     (remove #(= 1 (count (val %)))))) 

(let [seq [{:attribute :one 
      :other-things :bob} 
      {:attribute :one 
      :other-things :smith} 
      {:attribute :two 
      :other-things :blah}]] 
    (dups-with-function seq :attribute)) 

salidas:

([:one 
    [{:attribute :one, :other-things :bob} 
    {:attribute :one, :other-things :smith}]]) 

Si usted tiene una lista de objetos de Java y desea encontrar todos los que tienen duplicados primeros nombres:

(dups-with-function my-list #(.getFirstName %)) 

Answer 4

filtro Mínimo y frecuencias oneliner que hace el trabajo:

(filter #(< 1 ((frequencies col) %)) col) 

Sin embargo se lleva a cabo mal en grandes datos. Deberá ayudar al compilador diciendo:

(let [ freqs (frequencies col) ] 
    (filter #(< 1 (freqs %)) col))