¿Hay alguna manera de hacer que SAS se detenga con la primera advertencia o error?

Question

A SAS le gusta continuar el proceso bien después de advertencias y errores, por lo que a menudo necesito desplazarme hacia atrás en las páginas del registro para encontrar un problema. ¿Hay una mejor manera? Me gustaría que se detenga tan pronto como aparezca el primer error o advertencia para que pueda solucionarlo y vuelva a intentarlo.

Answer 1

La opción ERRORES = 1 se sugirió anteriormente, pero eso solo detiene la escritura de los mensajes ERROR en el registro. Sugeriría otra opción del sistema, ERRORABEND, que evitará que el programa siga procesando la mayoría de los errores. No conozco una opción para finalizar el procesamiento debido a las advertencias, pero creo que podría agregar una macro como la siguiente para detener el procesamiento.

%macro check_for_errors; 
    %if &syserr > 0 %then %do; 
     endsas; 
    %end; 
%mend check_for_errors; 

data test1; 
    <data step code> 
run; 
%check_for_errors; 

Puede repetir la llamada a la macro después de cada etapa de su programa, y ​​debe terminar en el punto de que el código de error es cualquier cosa menos 0.

Answer 2

frecuencia hago algo similar a RWill, pero envolver todo mi programa en una macro. Después de cada paso DATA, PROC SQL, PROC SORT, etc. Compruebo un código de error (& SYSERR o & SQLRC). Si no es cero, salto hasta el final.

Más detalles y código aquí: https://heuristically.wordpress.com/2012/02/09/return-codes-errors-sas/

no puedo usar endsas a causa de cómo el sistema de lotes de nuestra organización lleva a cabo programas independientes en una sola sesión de SAS RWill.

Answer 3

Una opción es reemplazar run con run &g_cancel, y proc sql; con proc sql &g_noexec;. Inicialmente, &g_cancel y &g_noexec están desactivados, por lo que todo se ejecuta.

en golpear un error (ya sea %sys_rc, %sql_rc o el uso de referirse a la lógica de negocio) establece &g_cancel para cancelar y &g_noexec a noexec.

Esto debería evitar que se ejecuten los siguientes pasos: obviamente las variables macro se pueden omitir para los pasos que tienen que ejecutarse independientemente (por ejemplo, un tidy up) o verificar antes de realizar pasos puramente en macro.

Nota para los usuarios de Enterprise Guide: La única advertencia es que si está ejecutando múltiples elementos de código en la misma sesión tendrá que restablecer los términos de error al inicio de cada elemento de código, no sea que los errores no relacionados detengan el funcionamiento.

Answer 4

He estado usando la macro %runquit recientemente. Funciona bien para trabajos por lotes y sesiones interactivas (no cierra la sesión, simplemente deja de ejecutar el código).

Fuente: http://www.cpc.unc.edu/research/tools/data_analysis/sas_to_stata/sas-macros/runquit.html

Para utilizarlo es básicamente escribir %runquit; al final de cualquier paso de datos o PROC en lugar de escribir su habitual run o quit comunicado.

Código:

%macro runquit; 
    ; run; quit; 
    %if &syserr. ne 0 %then %do; 
    %abort cancel; 
    %end; 
%mend runquit; 

uso Datastep:

data something; 
* do some stuff; 
%runquit; 

uso PROC:

proc sql; 
    * do some stuff; 
%runquit; 

No es tan bonito cuando la lectura a través del código, pero sí hacer que la depuración de un montón más fácil.

Answer 5

Como complemento a la respuesta de Rwill:

Si está utilizando un proceso almacenado (STP), que es también muy agradable para no mostrar el registro a los usuarios cuando se produce un error y para eliminar el "registro Mostrar SAS" botón .

que se pueden lograr con esta fuente

%macro checkcc; 
    options obs=max no$syntaxcheck; 
    %if (&syscc gt 4) %then 
     %do; 
      data _null_; 
       file _webout; 
       put "<h3>Sorry, your request was not processed successfully.<h3>"; 
       rc = stpsrvset('program error', 0); 
      run; 
     %end; 
    %let syscc=0; 
%mend checkcc; 
%checkcc; 

: http://support.sas.com/kb/16/225.html

Y aquí es una versión mejorada que hice para mostrar aún el error en el formato JSON.

%macro checkErrors; 
    options obs=max no$syntaxcheck; 
    %let old = %sysfunc(stpsrv_header(Content-type, application/json%str(;) charset=utf-8)); 
    %put &=syscc; %put &=syserr; %put &=sysrc; %put &=syswarningtext; %put &=syserrortext; 
    %if (&syscc gt 4) %then %do; 
     data _null_; 
      file _webout; 
      put '{'; 
      put ' "success":"false"'; 
      put ' ,"message":"' "&syserrortext" '"'; 
      put ' ,"syscc":"' "&syscc" '"'; 
      put '}'; 
      rc = stpsrvset('program error', 0); 
      run; 
     %end; 
    %let syscc=0; 
%mend checkErrors; 
%checkErrors; 

y HTML versión:

%macro checkErrors_HTML; 
    options obs=max no$syntaxcheck; 
    %if (&syscc gt 4) %then %do; 
     data _null_; 
      file _webout; 
      put '<!doctype html> '; 
      put '<html> '; 
      put ' <head> '; 
      put '  <title>Error</title> '; 
      put ' </head> '; 
      put ' <body> '; 
      put '  <h1>An Error Occured</h1>'; 
      put '  <p>' "&syserrortext" '</>'; 
      put ' </body>'; 
      put '</html>'; 
      rc = stpsrvset('program error', 0); 
      run; 
     %end; 
    %let syscc=0; 
%mend checkErrors_HTML; 
%checkErrors_HTML;