Grupo de líneas múltiples en campos múltiples - VB.NET, Anónimo, clave

Question

Estoy perplejo. Necesito ayuda. Tengo un objeto DTO con datos duplicados de dirección del paciente. Necesito obtener solo las direcciones únicas.

Dim PatientAddressDto = New List(Of PatientAddress) 

{Populate PatientAddressDto with lots of duplicate data} 

PatientAddressDto = (From d In PatientAddressDto 
        Group d By PatientAddressDtoGrouped = New PatientAddress With { 
                   .Address1 = d.Address1, 
                   .Address2 = d.Address2, 
                   .City = d.City, 
                   .State = d.State, 
                   .Zip = d.Zip 
                   } 
        Into Group 
        Select New PatientAddress With { 
                .Address1 = PatientAddressDtoGrouped.Address1, 
                .Address2 = PatientAddressDtoGrouped.Address2, 
                .City = PatientAddressDtoGrouped.City, 
                .State = PatientAddressDtoGrouped.State, 
                .Zip = PatientAddressDtoGrouped.Zip 
                }).ToList() 

he intentado lo siguiente sin suerte:

PatientAddressDto = (From d In PatientAddressDto 
        Select New PatientAddress With { 
                .Address1 = d.Address1, 
                .Address2 = d.Address2, 
                .City = d.City, 
                .State = d.State, 
                .Zip = d.Zip 
                }).Distinct  

y también

PatientAddressDto = PatientAddressDto.GroupBy(Function(p) New PatientAddress With { 
                .Address1 = p.Address1, 
                .Address2 = p.Address2, 
                .City = p.City, 
                .State = p.State, 
                .Zip = p.Zip 
                }) 

Answer 1

Puede utilizar un anonymous type y hacer uso de la Key keyword a fin de que la igualdad de comportarse de la forma esperada (no es necesario para C#).

Cambiar la agrupación especificando el prefijo Key y eliminar el uso PatientAddress:

Group d By PatientAddressDtoGrouped = New With { 
    Key .Address1 = d.Address1, 
    Key .Address2 = d.Address2, 
    Key .City = d.City, 
    Key .State = d.State, 
    Key .Zip = d.Zip 
} 

Answer 2

Su probablemente porque PatientAddress no anulan GetHashCode y Equals. Una alternativa es para nosotros un anonymous type para la agrupación. Trate de escribir:

Group d By PatientAddressDtoGrouped = New With { Key .Address1 = d.Address1, .... 

Answer 3

He encontrado el siguiente código al trabajo que lleva a cabo esencialmente la agrupación que yo quiero, y poblar el nuevo objeto de tipo PatientAddress por lo tanto, eliminando el uso de objetos anónimos y la palabra clave Key.

Quizás alguien pueda explicarlo, por el momento no puedo. Que tengas un buen día.

Dim PatientAddressDto = New List(Of PatientAddress) 

{Populate PatientAddressDto with lots of duplicate data} 

PatientAddressDto = (From d In PatientAddressDto 
        Group d By d.Address1, 
           d.Address2, 
           d.City, 
           d.State, 
           d.Zip Into g = 
        Group Let grp = New PatientAddress With {.Address1 = Address1, 
                   .Address2 = Address2, 
                   .City = City, 
                   .State = State, 
                   .Zip = Zip} 
        Select grp).ToList()