¿Cómo puedo cambiar el nombre de mis limitaciones

Question

Retitulé una tabla en mi base de datos con

EXEC sp_rename 'tblOldAndBusted', 'tblNewAndShiny' 

y todas las restricciones de claves foráneas se han actualizado para el nuevo nombre de la tabla, pero que todavía están nombradas basan en el antiguo nombre de la tabla . Por ejemplo, ahora tengo FK_tblOldAndBusted_tblTastyData pero me gustaría tener FK_tblNewAndShiny_tblTastyData.

¿Hay alguna manera fácil de escribir esto?

Además, ¿estoy siendo demasiado anal? Sé que la base de datos funciona bien con el nombre de la tabla anterior en las restricciones, pero se siente como broken windows.

Answer 1

Probar:

exec sp_rename 'FK_tblOldAndBusted_tblTastyData', 'FK_tblNewAndShiny_tblTastyData', 'object' 

Además, hay un error en relación con el cambio de nombre este tipo de cosas cuando se trabaja con schema no predeterminada.

Cannot rename a default constraint for a table in a schema which is not dbo by rsocol @Microsoft Connect

Answer 2

Si hay demasiados para cambiar el nombre, ¿qué hay de exportación a volcar, editar el vertedero en cualquier editor de texto de elección para reemplazar el nombre de la tabla, y luego restaurar de volcado? Me refiero a exportar el vertedero de solo restricciones, no todas.

Answer 3

Si alguien está interesado, solo tuve que cambiar el nombre de todas las restricciones predeterminadas para un campo de auditoría llamado "FechaIntroducida" a un patrón específico. Actualiza y reemplaza según sea necesario. Espero que esto ayude y pueda ser un punto de partida.

DECLARE @TableName VARCHAR(255), @ConstraintName VARCHAR(255) 
DECLARE constraint_cursor CURSOR 
    FOR 
     select b.name, c.name from 
     sys.all_columns a 
     inner join 
     sys.tables b 
     on 
     a.object_id = b.object_id 
     inner join 
     sys.default_constraints c 
     on a.default_object_id = c.object_id 
     where 
      b.name <> 'sysdiagrams' 
      and a.name = 'EnteredDate' -- column name 
      and b.type = 'U' 

OPEN constraint_cursor 
FETCH NEXT FROM constraint_cursor INTO @TableName, @ConstraintName 

WHILE @@FETCH_STATUS = 0 
    BEGIN 
     DECLARE @SqlScript VARCHAR(255) = '' 
     SET @SqlScript = 'sp_rename ' + @ConstraintName + ', ''DF_' + @TableName + '_EnteredDate'', ''object''' 
     EXEC(@SqlScript) 
     SELECT @TableName, @ConstraintName, 'DF_' + @TableName + '_EnteredDate', @SqlScript 
     FETCH NEXT FROM constraint_cursor INTO @TableName, @ConstraintName 
    END 
CLOSE constraint_cursor; 
DEALLOCATE constraint_cursor; 

Answer 4

Después de un poco más de excavación, descubrí que en realidad tiene que ser en esta forma: la escritura

EXEC sp_rename N'schema.MyIOldConstraint', N'MyNewConstraint', N'OBJECT' 

Source

Answer 5

de user906573 base. Genere una secuencia de comandos para cambiar el nombre de todos los valores predeterminados en la base de datos. Útil para corregir restricciones que no fueron nombradas explícitamente en el momento de creación.

-- 
-- Generates a script to rename defaults to the pattern DF_tablename_columnname 
-- 

DECLARE @TableName VARCHAR(255), @ConstraintName VARCHAR(255), @ColumnName varchar(255), @SchemaName varchar(255) 
DECLARE constraint_cursor CURSOR 
    FOR 
     select b.name, c.name, a.name, sc.name 
     from sys.all_columns a 
     inner join sys.tables b on a.object_id = b.object_id 
     join sys.schemas sc on b.schema_id = sc.schema_id 
     inner join sys.default_constraints c on a.default_object_id = c.object_id 
     where 
      b.name <> 'sysdiagrams' 
      and b.type = 'U' 

OPEN constraint_cursor 
FETCH NEXT FROM constraint_cursor INTO @TableName, @ConstraintName, @ColumnName, @SchemaName 

WHILE @@FETCH_STATUS = 0 
    BEGIN 
     DECLARE @SqlScript VARCHAR(255) = '' 
     SET @SqlScript = 'sp_rename ''' + @SchemaName + '.' + @ConstraintName + ''', ''' + @SchemaName + '.DF_' + @TableName + '_' + @ColumnName + ''', ''object''' + char(13) + char(10) + 'GO' + char(13) + char(10) 
     --EXEC(@SqlScript) 
     print @sqlscript 
     FETCH NEXT FROM constraint_cursor INTO @TableName, @ConstraintName, @ColumnName, @SchemaName 
    END 
CLOSE constraint_cursor; 
DEALLOCATE constraint_cursor; 

Answer 6

No soy un gran fan de los cursores y esto se puede escribir de forma mucho más simple.

DECLARE @SQLCmd varchar(MAX) = '' 
SELECT 
    @SQLCmd += 'EXEC sp_rename ''' + dc.name + ''', ''DF' + 
       OBJECT_NAME(dc.parent_object_id) + c.name + ''', ''OBJECT'';' 
FROM 
    sys.default_constraints dc 
    JOIN sys.columns c 
     ON c.object_id = dc.parent_object_id 
     AND c.column_id = dc.parent_column_id 
WHERE 
    dc.name != 'DF' + object_name(dc.parent_object_id) + c.name 
    AND OBJECT_NAME(dc.parent_object_id) != 'dtproperties' 
EXEC(@SqlCmd) 

Answer 7

Sé que este hilo está un poco anticuado, pero quería publicar mi alternativa a la respuesta de @ foxfire ya que le hice algunas modificaciones. Hice que tomara un trozo más pequeño de los nombres cuando me encontré con la base de datos donde había tantos cambios de nombre que hizo truncar a @sql. También agregué el manejo de errores para romper así como los nombres de esquema para manejar diferentes esquemas distintos de dbo. Decidí no usar una prueba de inicio para que se pudiera usar entre múltiples versiones de servidor sql. La cláusula where se puede manipular para cumplir con la intención original del OP.

BEGIN TRAN 

DECLARE @sql varchar(MAX) = '...' 

WHILE LEN(@sql) > 0 BEGIN 
     SET @sql = ''; 

     SELECT TOP 50 @sql = @sql 
       + 'EXEC sp_rename N''' + SCHEMA_NAME(dc.[schema_id]) + '.' + dc.name 
       + ''', N''DF_' + OBJECT_NAME(dc.parent_object_id) + '_' + c.name 
       + ''', ''OBJECT'';' + CHAR(10) 
     FROM sys.default_constraints dc 
     inner join sys.columns c 
       ON c.object_id = dc.parent_object_id AND c.column_id = dc.parent_column_id 
     WHERE dc.name LIKE 'DF[_][_]%' -- rename any auto named defaults 

     PRINT @sql 
     EXEC(@sql) 

     IF @@ERROR <> 0 BEGIN 
       IF @@TRANCOUNT > 0 ROLLBACK TRAN 
       BREAK; 
     END 
END 

IF @@TRANCOUNT > 0 COMMIT TRAN 
--IF @@TRANCOUNT > 0 ROLLBACK TRAN