Convertir dateTime a unix epoch en xslt

Question

Tengo una variable dateTime, y quiero convertirla a un valor decimal de epoch. ¿Cómo se puede hacer esto?

He intentado utilizar:

seconds-from-duration($time, xs:dateTime('1970-01-01T00:00:00')) 

pero simplemente devuelve 0.

consejos favor. Gracias.

Answer 1

Esta transformación:

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema"> 
    <xsl:output method="text"/> 

<xsl:template match="/"> 
    <xsl:sequence select="current-dateTime()"/> 

    <xsl:sequence select= 
    "(current-dateTime() - xs:dateTime('1970-01-01T00:00:00')) 
    div 
    xs:dayTimeDuration('PT1S') 
    "/> 
</xsl:template> 
</xsl:stylesheet> 

cuando se aplica en cualquier documento XML (no se utiliza), produce el resultado deseado - la fecha actual en tiempo y su época Unix (el número de segundos desde el 1 de/1/1970):

2010-08-12T06:26:54.273-07:00 1281594414.273 

Answer 2

Como un XPath que no utiliza división pero extractos de la duración:

for $i in (current-dateTime()-xs:dateTime('1970-01-01T00:00:00Z')) 
    return ((days-from-duration($i)*86400)+(hours-from-duration($i)*3600)+(minutes-from-duration($i)*60)+(seconds-from-duration($i))) 

Answer 3

A pure xsl 1.0 lib ejemplo:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:date="https://github.com/ilyakharlamov/pure-xsl/date" 
    version="1.0"> 
    <xsl:import href="https://raw.github.com/ilyakharlamov/pure-xsl/master/date.xsl"/> 
    <xsl:template match="/"> 
     <xsl:variable name="time_as_timestamp" select="1365599995640"/> 
     <xsl:text>time_as_timestamp:</xsl:text><xsl:value-of select="$time_as_timestamp"/><xsl:text>&#x0A;</xsl:text> 
     <xsl:variable name="time_as_xsdatetime"> 
      <xsl:call-template name="date:date-time"> 
       <xsl:with-param name="timestamp" select="$time_as_timestamp"/> 
      </xsl:call-template> 
     </xsl:variable> 
     <xsl:text>time_as_xsdatetime:</xsl:text><xsl:value-of select="$time_as_xsdatetime"/><xsl:text>&#x0A;</xsl:text> 
     <xsl:text>converted back:</xsl:text> 
     <xsl:call-template name="date:timestamp"> 
      <xsl:with-param name="date-time" select="$time_as_xsdatetime"/> 
     </xsl:call-template> 
    </xsl:template> 
</xsl:stylesheet> 

de salida:

time_as_timestamp: 1365599995640
time_as_xsdatetime: 2013-04-10T13: 19: 55.640Z
convierte de nuevo: 1365599995640