Encontrar el valor máximo del elemento Y su posición usando CUDA Thrust

Question

¿Cómo obtengo no solo el valor sino también la posición del elemento máximo (mínimo) (res.val y res.pos)?

thrust::host_vector<float> h_vec(100); 
thrust::generate(h_vec.begin(), h_vec.end(), rand); 
thrust::device_vector<float> d_vec = h_vec; 

T res = -1; 
res = thrust::reduce(d_vec.begin(), d_vec.end(), res, thrust::maximum<T>()); 

Answer 1

No utilice thrust::reduce. Utilice thrust::max_element (thrust::min_element) en thrust/extrema.h:

thrust::host_vector<float> h_vec(100); 
thrust::generate(h_vec.begin(), h_vec.end(), rand); 
thrust::device_vector<float> d_vec = h_vec; 

thrust::device_vector<float>::iterator iter = 
    thrust::max_element(d_vec.begin(), d_vec.end()); 

unsigned int position = iter - d_vec.begin(); 
float max_val = *iter; 

std::cout << "The maximum value is " << max_val << " at position " << position << std::endl; 

Tenga cuidado al adelantar un rango de vacío a max_element - usted no será capaz de eliminar la referencia de forma segura el resultado.

Answer 2

Jared Hoberock ya ha respondido satisfactoriamente a esta pregunta. Deseo proporcionar a continuación un ligero cambio para tener en cuenta el caso común cuando la matriz ha sido asignada por cudaMalloc y no a través de un contenedor device_vector.

La idea es envolver un device_pointerdev_ptr alrededor del cudaMalloc 'ed puntero prima, echando la salida de min_element (estoy considerando el mínimo en lugar del máximo sin ninguna pérdida de generalidad) a un device_pointermin_ptr y luego encontrar la valor mínimo como min_ptr[0] y la posición por &min_ptr[0] - &dev_ptr[0].

#include "cuda_runtime.h" 
#include "device_launch_paraMeters.h" 

#include <thrust\device_vector.h> 
#include <thrust/extrema.h> 

/***********************/ 
/* CUDA ERROR CHECKING */ 
/***********************/ 
#define gpuErrchk(ans) { gpuAssert((ans), __FILE__, __LINE__); } 
inline void gpuAssert(cudaError_t code, const char *file, int line, bool abort=true) 
{ 
    if (code != cudaSuccess) 
    { 
     fprintf(stderr,"GPUassert: %s %s %d\n", cudaGetErrorString(code), file, line); 
     if (abort) exit(code); 
    } 
} 

/********/ 
/* MAIN */ 
/********/ 
int main() { 

    srand(time(NULL)); 

    const int N = 10; 

    float *h_vec = (float *)malloc(N * sizeof(float)); 
    for (int i=0; i<N; i++) { 
     h_vec[i] = rand()/(float)(RAND_MAX); 
     printf("h_vec[%i] = %f\n", i, h_vec[i]); 
    } 

    float *d_vec; gpuErrchk(cudaMalloc((void**)&d_vec, N * sizeof(float))); 
    gpuErrchk(cudaMemcpy(d_vec, h_vec, N * sizeof(float), cudaMemcpyHostToDevice)); 

    thrust::device_ptr<float> dev_ptr = thrust::device_pointer_cast(d_vec); 

    thrust::device_ptr<float> min_ptr = thrust::min_element(dev_ptr, dev_ptr + N); 

    float min_value = min_ptr[0]; 
    printf("\nMininum value = %f\n", min_value); 
    printf("Position = %i\n", &min_ptr[0] - &dev_ptr[0]); 

}