Descargar un archivo de Internet programáticamente con un evento Progress utilizando Delphi e Indy

Question

Necesito una forma de descargar un archivo de Internet usando Delphi a través de HTTP, que incluye un evento Progress, estoy buscando un método que utiliza el Componentes Indy.

estoy usando Delphi 7.

Gracias de antemano.

Answer 1

He codificado este ejemplo, utilizando un solo HTTP GET, con Indy 10, espero que funcione con Indy 9 también:

uses 
    {...} IdHTTP, IdComponent; 

type 
    TFormMain = class(TForm) 
    {...} 
    private 
    {...} 
    procedure HttpWork(ASender: TObject; AWorkMode: TWorkMode; AWorkCount: Int64); 
    end; 
{...} 

procedure TFormMain.Button1Click(Sender: TObject); 
var 
    Http: TIdHTTP; 
    MS: TMemoryStream; 
begin 
    Http := TIdHTTP.Create(nil); 
    try 
    MS := TMemoryStream.Create; 
    try 
     Http.OnWork:= HttpWork; 

     Http.Get('http://live.sysinternals.com/ADExplorer.exe', MS); 
     MS.SaveToFile('C:\ADExplorer.exe'); 

    finally 
     MS.Free; 
    end; 
    finally 
    Http.Free; 
    end; 
end; 

procedure TFormMain.HttpWork(ASender: TObject; AWorkMode: TWorkMode; AWorkCount: Int64); 
var 
    Http: TIdHTTP; 
    ContentLength: Int64; 
    Percent: Integer; 
begin 
    Http := TIdHTTP(ASender); 
    ContentLength := Http.Response.ContentLength; 

    if (Pos('chunked', LowerCase(Http.Response.TransferEncoding)) = 0) and 
    (ContentLength > 0) then 
    begin 
    Percent := 100*AWorkCount div ContentLength; 

    MemoOutput.Lines.Add(IntToStr(Percent)); 
    end; 
end;