Obtener URL actual en IE con Visual Basic

Question

Estoy trabajando con el objeto de Internet Explorer en Visual Basic. ¿Hay alguna manera de copiar la URL actual que IE muestra para poder pegarla en otro lugar con mi portapapeles?

Answer 1

Suponiendo que ya haya identificado la ventana de IE, que en sí es un poco más complicado - puedo más detalles sobre esto, si es necesario:

Dim ieIEWindow As SHDocVw.InternetExplorer 
Dim sIEURL As String 

'Set your IE Window 

sIEURL = ieIEWindow.LocationURL 

Para obtener la ventana de IE, tendrá que hacer referencia a la biblioteca Microsoft Internet Controls (ieframe.dll) en el editor de VBA yendo a Tools =>References... y seleccionándolo de la lista. Si ese artículo no está disponible, el archivo .dll para mí se encuentra en C:\Windows\System32\ieframe.dll.

Una vez que se establece la referencia, tendrá acceso a la biblioteca llamada SHDocVw en su código.

se puede agarrar la ventana de IE (suponiendo único abierto) utilizando la siguiente (no probado, modificado/reducida de mi propio código de trabajo):

Public Function GrabIEWindow() As SHDocView.InternetExplorer 

Dim swShellWindows As New SHDocVw.ShellWindows 
Dim ieOpenIEWindow As SHDocVw.InternetExplorer 

    Set GrabIEWindow = Nothing 

    ' Look at the URLs of any active Explorer windows 
    ' (this includes WINDOWS windows, not just IE) 
    For Each ieOpenIEWindow In objShellWindows 

     ' Check the I.E. window to see if it's pointed 
     ' to a web location (http) 
     If Left$(ieOpenIEWindow.LocationURL, 4) = "http" Then 
      ' If so, set this window as the one to use. 
      ' This will need to be modified to create 
      ' a list if you want to select from more 
      ' than one open window 

      ' Optional grab the HWND for later reference... 
      Dim lWindowID As Long 
      lWindowID = ieOpenIEWindow.HWND 

      Set GrabIEWindow = ieOpenIEWindow 

      Exit Function 
     End If 

    Next OpenIEWindow 

End Function 

Lo anterior puede también ser modificado para permitir una selección de múltiples ventanas abiertas de IE.

Answer 2

¡Maldición! Esto me recuerda a mi vb6 días :)

Ok aquí es lo que tengo. Si hay más de 1 ventana IE, entonces tomará la última ventana activa (Actual) IE, de lo contrario, si solo hay una ventana, se necesitaría eso.

'~~> Set a reference to Microsoft Internet Controls 

'~~> The GetWindow function retrieves the handle of a window that has 
'~~> the specified relationship (Z order or owner) to the specified window. 
Private Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, _ 
ByVal wCmd As Long) As Long 

'~~> The GetForegroundWindow function returns the handle of the foreground 
'~~> window (the window with which the user is currently working). 
Private Declare Function GetForegroundWindow Lib "user32"() As Long 

Sub GetURL() 
    Dim sw As SHDocVw.ShellWindows 
    Dim objIE As SHDocVw.InternetExplorer 
    Dim topHwnd As Long, nextHwnd As Long 
    Dim sURL As String, hwnds As String 

    Set sw = New SHDocVw.ShellWindows 

    '~~> Check the number of IE Windows Opened 
    '~~> If more than 1 
    hwnds = "|" 
    If sw.Count > 1 Then 
     '~~> Create a string of hwnds of all IE windows 
     For Each objIE In sw 
      hwnds = hwnds & objIE.hwnd & "|" 
     Next 

     '~~> Get handle of handle of the foreground window 
     nextHwnd = GetForegroundWindow 

     '~~> Check for the 1st IE window after foreground window 
     Do While nextHwnd > 0 
      nextHwnd = GetWindow(nextHwnd, 2&) 
      If InStr(hwnds, "|" & nextHwnd & "|") > 0 Then 
       topHwnd = nextHwnd 
       Exit Do 
      End If 
     Loop 

     '~~> Get the URL from the relevant IE window 
     For Each objIE In sw 
      If objIE.hwnd = topHwnd Then 
       sURL = objIE.LocationURL 
       Exit For 
      End If 
     Next 
    '~~> If only 1 was found 
    Else 
     For Each objIE In sw 
      sURL = objIE.LocationURL 
     Next 
    End If 

    Debug.Print sURL 

    Set sw = Nothing: Set objIE = Nothing 
End Sub 

NOTA: No he hecho ninguna gestión de errores. Estoy seguro de que puede encargarse de eso;)