Desactivar todos los índices no agrupados

Question

que seleccionar una serie de índices no agrupados de mi base de datos con la siguiente:

SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

me gustaría ejecutar el siguiente sobre cada uno de los resultados:

ALTER INDEX indexName ON tableName DISABLE 

¿Cómo voy a hacer esto? ¿Hay una mejor manera?

EDITAR

que estoy haciendo esto con el fin de truncar las tablas, a continuación, la reconstrucción con "ALTER bla índice en la tabla RECONSTRUIR". Esto necesita ser automatizado, por lo que descartar y reconstruir sería una actividad de mantenimiento algo mayor que preferiría evitar. ¿Es este un mal plan? Necesito un medio para vaciar mesas con un mínimo de gastos generales.

Answer 1

Usted puede construir las consultas en una instrucción de selección, así:

DECLARE @sql AS VARCHAR(MAX)=''; 

SELECT @sql = @sql + 
'ALTER INDEX ' + sys.indexes.name + ' ON ' + sys.objects.name + ' DISABLE;' +CHAR(13)+CHAR(10) 
FROM 
    sys.indexes 
JOIN 
    sys.objects 
    ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
    AND sys.objects.type_desc = 'USER_TABLE'; 

EXEC(@sql); 

Caracteres 13 y 10 son la línea de alimentación/retornos de carro, por lo que puede comprobar la salida mediante la sustitución de EXEC con PRINT, y será más legible.

Answer 2

Cree una variable de tabla con los índices y los nombres de tabla. Use un ciclo para iterar sobre ellos y ejecute una declaración SQL dinámica para cada uno de ellos.

declare @Indexes table 
(
    Num  int identity(1,1) primary key clustered, 
    TableName nvarchar(255), 
    IndexName nvarchar(255) 
) 

INSERT INTO @Indexes 
(
    TableName, 
    IndexName 
) 
SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

DECLARE @Max INT 
SET @Max = @@ROWCOUNT 

SELECT @Max as 'max' 
SELECT * FROM @Indexes 

DECLARE @I INT 
SET @I = 1 

DECLARE @TblName NVARCHAR(255), @IdxName NVARCHAR(255) 

DECLARE @SQL NVARCHAR(MAX) 

WHILE @I <= @Max 
BEGIN 
    SELECT @TblName = TableName, @IdxName = IndexName FROM @Indexes WHERE Num = @I 
    SELECT @SQL = N'ALTER INDEX ' + @IdxName + N' ON ' + @TblName + ' DISABLE;' 

    EXEC sp_sqlexec @SQL  

    SET @I = @I + 1 

END 

Answer 3

otoh tal vez sería mejor a DROP vez que DISABLE (o se trata de un diff sintáctica pequeña lil entre Oracle y MS SQL? :-) La razón que menciono es que recuerdo tablas que fueron repobladas y excplicilty desnormalizado dos veces al día y estábamos MALDECIENDO todos los índices para forzar a DB a reconstruir ambos índices y planes de ejecución de sproc después de cargar una nueva fecha y reconstruir todos los índices.

Por supuesto, teníamos un script separado para eso, ya que una vez que los sueltas, los índices ya no están en las tablas del sistema.

Answer 4

Usar un cursor para guiar las cosas es más idiomático que una tabla temporal (y un poco más breve). Para volver a habilitar los índices, reemplace DESACTIVAR con RECONSTRUIR.

DECLARE cur_indexes CURSOR FOR 
SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

DECLARE @TblName NVARCHAR(255), @IdxName NVARCHAR(255) 

DECLARE @SQL NVARCHAR(MAX) 

open cur_indexes 
fetch next from cur_indexes into @TblName, @IdxName 

WHILE @@FETCH_STATUS = 0 
BEGIN 
    SELECT @SQL = N'ALTER INDEX ' + @IdxName + N' ON ' + @TblName + ' DISABLE;' 

    EXEC sp_sqlexec @SQL  

    fetch next from cur_indexes into @TblName, @IdxName 
END 

close cur_indexes 
deallocate cur_indexes