Vim: Use textwidth más corto en los comentarios y docstrings

Question

Desde el poderoso PEP 8:

[P] límite de arrendamiento todas las líneas hasta un máximo de 79 caracteres. Para el flujo de bloques largos de texto (cadenas de texto o comentarios), se recomienda limitar la longitud a 72 caracteres.

Al editar el código Python en Vim, volví mi textwidth a 79, y Vim ajusta automáticamente largas líneas de código Python para mí cuando me golpeó el límite de caracteres.

Pero en los comentarios y las cadenas de texto, necesito ajustar el texto a 72 caracteres. ¿Hay alguna manera de hacer que Vim configure automáticamente textwidth en 72 cuando estoy en un comentario o docstring, y volver a configurarlo cuando termine?

Answer 1

Por lo tanto, nunca he hecho ningún script Vim antes, pero basado en this question about doing something similar in C y this tip for checking if you're currently in a comment, he pirateado una solución.

Por defecto, este utiliza el ancho de PEP8-sugerido de 79 caracteres para las líneas normales y 72 caracteres para los comentarios, pero se los puede sustituir por let ting g:python_normal_text_width o g:python_comment_text_width las variables, respectivamente. (Personalmente, envuelvo las líneas normales a 78 caracteres.)

Deje caer a este bebé en su .vimrc y ya estará listo para empezar. Puedo empaquetar esto como un complemento más adelante.

function! GetPythonTextWidth() 
    if !exists('g:python_normal_text_width') 
     let normal_text_width = 79 
    else 
     let normal_text_width = g:python_normal_text_width 
    endif 

    if !exists('g:python_comment_text_width') 
     let comment_text_width = 72 
    else 
     let comment_text_width = g:python_comment_text_width 
    endif 

    let cur_syntax = synIDattr(synIDtrans(synID(line("."), col("."), 0)), "name") 
    if cur_syntax == "Comment" 
     return comment_text_width 
    elseif cur_syntax == "String" 
     " Check to see if we're in a docstring 
     let lnum = line(".") 
     while lnum >= 1 && (synIDattr(synIDtrans(synID(lnum, col([lnum, "$"]) - 1, 0)), "name") == "String" || match(getline(lnum), '\v^\s*$') > -1) 
      if match(getline(lnum), "\\('''\\|\"\"\"\\)") > -1 
       " Assume that any longstring is a docstring 
       return comment_text_width 
      endif 
      let lnum -= 1 
     endwhile 
    endif 

    return normal_text_width 
endfunction 

augroup pep8 
    au! 
    autocmd CursorMoved,CursorMovedI * :if &ft == 'python' | :exe 'setlocal textwidth='.GetPythonTextWidth() | :endif 
augroup END 

Answer 2

¡La respuesta aceptada es genial! Sin embargo, no es compatible con el hábito que tengo para formatear/editar comentarios: realizo mis ediciones y luego uso el comando gqj, que es esencialmente "reformatear la línea actual combinada con la siguiente". Luego presiono '.' para repetir eso para cada línea (el comando mismo avanza el cursor a la siguiente línea). No sé muy bien el lenguaje de scripting vim, por lo que alguien puede agregar soporte para esto a la respuesta aceptada. Mientras tanto, lo que he hecho es asignar una tecla de función (F6) para cambiar el textwidth a 72, formatear la línea y luego cambiar el textwidth de nuevo a 79.

nmap <F6> :set textwidth=72<CR>gqj:set textwidth=79<CR> 

Ahora, cuando estoy en una docstring, solo hago la edición, (ESC) y luego presiono F6 repetidamente hasta que todas las líneas estén formateadas apropiadamente.

Agregué mi comando de mapa y el script de respuesta aceptado a mi .vim/after/ftplugin/python.vim.