En groovy, ¿hay alguna forma de comprobar si un objeto tiene un método determinado?

Question

Suponiendo que tengo un objeto someObj de tipo indeterminado, me gustaría hacer algo como:

def value = someObj.someMethod() 

Donde no hay garantía de que 'someObj' implementa el método someMethod(), y si no lo hace, simplemente return null.

¿Hay algo así en Groovy, o debo envolverlo en un enunciado if con un cheque instanceof?

Answer 1

Uso respondsTo

class Foo { 
    String prop 
    def bar() { "bar" } 
    def bar(String name) { "bar $name" } 
} 

def f = new Foo() 

// Does f have a no-arg bar method 
if (f.metaClass.respondsTo(f, "bar")) { 
    // do stuff 
} 
// Does f have a bar method that takes a String param 
if (f.metaClass.respondsTo(f, "bar", String)) { 
    // do stuff 
} 

Answer 2

usted debería ser capaz de hacer algo como:

SomeObj.metaClass.getMetaMethod("someMethod") 

o puede caer de nuevo a la API buena reflexión de edad Java.

Answer 3

Sólo aplicar methodMissing en su clase:

class Foo { 
    def methodMissing(String name, args) { return null; } 
} 

Y entonces, cada vez que se intenta invocar un método que no existe, se obtendrá un valor nulo.

def foo = new Foo(); 
assert foo.someMethod(), null 

Para obtener más información, echa un vistazo aquí: http://groovy.codehaus.org/Using+methodMissing+and+propertyMissing

Answer 4

Esto se puede conseguir mediante el uso de getMetaMethod junto con el operador de navegación segura ?.:

def str = "foo" 
def num = 42 

def methodName = "length" 
def args = [] as Object[] 

assert 3 == str.metaClass.getMetaMethod(methodName, args)?.invoke(str, args); 
assert null == num.metaClass.getMetaMethod(methodName, args)?.invoke(num, args); 

Answer 5

si la clase:

MyClass.metaClass.methods*.name.any{it=='myMethod'}//true if exist 

si el objeto:

myObj.class.metaClass.methods*.name.any{it=='myMethod'}//true if exist