Obtención de exsl: node-set para trabajar en PHP

Tengo el siguiente código PHP, pero no está funcionando. No veo ningún error, pero tal vez estoy solo ciego. Estoy ejecutando esto en PHP 5.3.1.Obtención de exsl: node-set para trabajar en PHP

<?php 
$xsl_string = <<<HEREDOC 
<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" 
       xmlns="http://www.w3.org/1999/xhtml" 
       xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:exsl="http://exslt.org/common" 
       extension-element-prefixes="exsl"> 
    <xsl:template match="/"> 
    <p>Hello world</p> 
    <xsl:variable name="person"> 
     <firstname>Foo</firstname> 
     <lastname>Bar</lastname> 
     <email>[email protected]</email> 
    </xsl:variable> 
    <xsl:value-of select="exsl:node-set(\$person)/email"/> 
    </xsl:template> 
</xsl:stylesheet> 
HEREDOC; 

$xml_dom = new DOMDocument("1.0", "utf-8"); 
$xml_dom->appendChild($xml_dom->createElement("dummy")); 

$xsl_dom = new DOMDocument(); 
$xsl_dom->loadXML($xsl_string); 

$xsl_processor = new XSLTProcessor(); 
$xsl_processor->importStyleSheet($xsl_dom); 
echo $xsl_processor->transformToXML($xml_dom); 
?>

Este código debe de salida "Hola mundo" seguido de "[email protected]", pero no aparece la sección de correo electrónico. ¿Alguna idea de lo que está mal?

Geoffrey Lee

Fuente

2010-06-01 geofflee

buena pregunta (1). Vea mi respuesta para una explicación y una solución completa. –

El problema es que el código XSLT siempre tiene un espacio de nombres predeterminado.

Por lo tanto, los elementos <firstname>, <lastname> y <email> están en el espacio de nombres XHTML. Pero email está referenciado sin ningún prefijo en:

exsl:node-set($person)/email

XPath considera todos los nombres sin prefijo para estar en "ningún espacio de nombres". Intenta encontrar un elemento secundario de exsl:node-set($person) llamado email que está en "sin espacio de nombres" y esto no es correcto, porque su elemento secundario email está en el espacio de nombres xhtml. Por lo tanto, no se selecciona ningún nodo email y se genera.

Solución:

Esta transformación:

<xsl:stylesheet version="1.0" 
    xmlns="http://www.w3.org/1999/xhtml" 
    xmlns:x="http://www.w3.org/1999/xhtml" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:exsl="http://exslt.org/common" 
    exclude-result-prefixes="exsl x"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 

    <xsl:template match="/"> 
    <html> 
    <p>Hello world</p> 
    <xsl:variable name="person"> 
     <firstname>Foo</firstname> 
     <lastname>Bar</lastname> 
     <email>[email protected]</email> 
    </xsl:variable> 
    <xsl:text>&#xA;</xsl:text> 
    <xsl:value-of select="exsl:node-set($person)/x:email"/> 
    <xsl:text>&#xA;</xsl:text> 
    </html> 
    </xsl:template> 
</xsl:stylesheet>

cuando se aplica en cualquier documento XML (no se utiliza), produce el resultado deseado:

<html xmlns="http://www.w3.org/1999/xhtml" xmlns:x="http://www.w3.org/1999/xhtml"> 
    <p>Hello world</p> 
[email protected] 
</html>

Ten en cuenta:

La definición de espacio de nombres con el prefijo añadido x
La cambiado select atributo de <xsl:value-of>:

exsl:node-set($person)/x:email

Fuente

2010-06-01 13:06:54

Ah, eso tiene mucho sentido ahora. ¡Gracias por tu respuesta bien escrita! – geofflee

Obtención de exsl: node-set para trabajar en PHP

Respuesta

Cuestiones relacionadas