¿Cómo convierto una fecha/hora a hora de época (tiempo Unix/segundos desde 1970) en Perl?

Question

Dada una fecha/hora como una matriz de (año, mes, día, hora, minuto, segundo), cómo la convertiría a hora de época, es decir, la cantidad de segundos desde 1970-01-01 00:00: 00 GMT?

Pregunta adicional: Si se le da la fecha/hora como una cadena, ¿cómo la analizaría primero en la matriz (y, m, d, h, m, s)?

Answer 1

Esta es la forma más sencilla de obtener el tiempo UNIX:

use Time::Local; 
timelocal($second,$minute,$hour,$day,$month-1,$year); 

Nota el orden inverso de los argumentos y que enero es el mes 0. Para muchas más opciones, vea el módulo de CPAN DateTime.

En cuanto al análisis sintáctico, vea el módulo Date::Parse de CPAN. Si realmente necesita hacerse elegante con el análisis de fecha, el Date::Manip puede ser útil, aunque su propia documentación lo advierte, ya que lleva una gran cantidad de equipaje (sabe cosas como feriados comerciales comunes, por ejemplo) y otras soluciones son mucho Más rápido.

Si sabe algo sobre el formato de las fechas/horas que analizará, una simple expresión regular puede ser suficiente, pero probablemente sea mejor utilizar un módulo de CPAN adecuado. Por ejemplo, si sabe que las fechas siempre estarán en orden YMDHMS, use el módulo CPAN DateTime::Format::ISO8601.

---

Por mi propia referencia, si no otra cosa, a continuación es una función que uso para una aplicación en la que sé las fechas estarán siempre en orden YMDHMS con la totalidad o parte de la parte "HMS" opcional. Acepta cualquier delimitador (p. Ej., "2009-02-15" o "2009.02.15"). Devuelve el tiempo Unix correspondiente (segundos desde 1970-01-01 00:00:00 GMT) o -1 si no pudo analizarlo (lo que significa que es mejor asegurarse de que nunca necesitará legítimamente analizar la fecha 1969- 12-31 23:59:59). También presume que los dos dígitos del año XX hasta "69" se refieren a "20XX", de lo contrario "19XX" (por ejemplo, "50-02-15" significa 2050-02-15 pero "75-02-15" significa 1975- 02-15).

use Time::Local; 

sub parsedate { 
    my($s) = @_; 
    my($year, $month, $day, $hour, $minute, $second); 

    if($s =~ m{^\s*(\d{1,4})\W*0*(\d{1,2})\W*0*(\d{1,2})\W*0* 
       (\d{0,2})\W*0*(\d{0,2})\W*0*(\d{0,2})}x) { 
    $year = $1; $month = $2; $day = $3; 
    $hour = $4; $minute = $5; $second = $6; 
    $hour |= 0; $minute |= 0; $second |= 0; # defaults. 
    $year = ($year<100 ? ($year<70 ? 2000+$year : 1900+$year) : $year); 
    return timelocal($second,$minute,$hour,$day,$month-1,$year); 
    } 
    return -1; 
} 

Answer 2

Si está utilizando el módulo DateTime, puede llamar al método epoch() en un objeto DateTime, ya que eso es lo que piensa de como el tiempo UNIX.

El uso de DateTimes le permite convertir bastante fácilmente objetos de época, hasta la fecha.

Alternativly, localtime y gmtime convertirá una época en una matriz que contiene el día de mes y el año, y timelocal y timegm del Time::Local module hará lo contrario, la conversión de una serie de elementos de tiempo (segundos, minutos, días, ... , meses, etc.) en una época.

Answer 3

Si solo está buscando una utilidad de línea de comandos (es decir, no es algo que reciba llamadas de otras funciones), pruebe esta secuencia de comandos. Se supone la existencia de la fecha de GNU (presente en casi cualquier sistema Linux):

#! /usr/bin/perl -w 

use strict; 

$_ = (join ' ', @ARGV); 
$_ ||= <STDIN>; 

chomp; 

if (/^[\d.]+$/) { 
    print scalar localtime $_; 
    print "\n"; 
} 
else { 
    exec "date -d '$_' +%s"; 
} 

Así es como funciona:

$ Time now 
1221763842 

$ Time yesterday 
1221677444 

$ Time 1221677444 
Wed Sep 17 11:50:44 2008 

$ Time '12:30pm jan 4 1987' 
536790600 

$ Time '9am 8 weeks ago' 
1216915200 

Answer 4

para analizar una fecha, mira Date::Parse en CPAN.

Answer 5

Un filtro que convierte cualquier fecha en varios formatos relacionados con ISO (¿y quién usaría algo más después de leer the writings de Mighty Kuhn?) En la entrada estándar a segundo-desde-el-efeméride de tiempo en la salida estándar podría servir para ilustrar las dos partes:

martind@whitewater:~$ cat `which isoToEpoch` 
#!/usr/bin/perl -w 
use strict; 
use Time::Piece; 
# sudo apt-get install libtime-piece-perl 
while (<>) { 
    # date --iso=s: 
    # 2007-02-15T18:25:42-0800 
    # Other matched formats: 
    # 2007-02-15 13:50:29 (UTC-0800) 
    # 2007-02-15 13:50:29 (UTC-08:00) 
    s/(\d{4}-\d{2}-\d{2}([T ])\d{2}:\d{2}:\d{2})(?:\.\d+)? ?(?:\(UTC)?([+\-]\d{2})?:?00\)?/Time::Piece->strptime ($1, "%Y-%m-%d$2%H:%M:%S")->epoch - (defined ($3) ? $3 * 3600 : 0)/eg; 
    print; 
} 
martind@whitewater:~$ 

Answer 6

Mi analizador de fecha y hora favorita es DateTime::Format::ISO8601 Una vez que tenga que trabajar, tendrá un DateTime objeto, fácilmente convertible a Epoch segundos con época()

Answer 7

Get Date::Manip from CPAN, entonces:

use Date::Manip; 
$string = '18-Sep-2008 20:09'; # or a wide range of other date formats 
$unix_time = UnixDate(ParseDate($string), "%s"); 

edición:

Fecha :: i Manip es grande y lento, pero muy flexible en el análisis sintáctico, y es puro perl. Úselo si tiene prisa cuando escribe código y sabe que no tendrá prisa cuando lo esté ejecutando.

p. Ej. Úselo para analizar las opciones de línea de comando una vez en la puesta en marcha, pero no lo use analizando grandes cantidades de datos en un servidor web ocupado.

Ver the authors comments.

(Gracias al autor del primer comentario más abajo)

Answer 8

Posiblemente uno de los mejores ejemplos de 'Hay más de un camino para hacer esto", con o sin la ayuda de CPAN.

Si usted tiene control sobre lo que se pasa como una 'fecha/hora', sugiero que vaya por la ruta DateTime, ya sea usando una subclase específica Date :: Time :: Format, o usando DateTime :: Format :: Strptime si hay no es compatible con el formato de fecha loco (ver datetime FAQ para más detalles). En general, Date :: Time es el camino a seguir si quieres hacer algo serio con el resultado: pocas clases en CPAN son tan anal retentivo y obsesivo ively exacto.

Si esperas cosas raras de forma libre, inclúyelo en el método str2time() de Date::Parse, que te dará un valor de segundos después de la época que podrás ejecutar de manera perversa, sin la sobrecarga de Date::Manip .

Answer 9

Hay muchos módulos de manipulación de fechas en CPAN. Mi favorito particular es DateTime y puede usar el strptime modules para analizar las fechas en formatos arbitrarios. También hay muchos módulos DateTime :: Format en CPAN para manejar formatos de fecha especializados, pero strptime es el más genérico.

Answer 10

$ENV{TZ}="GMT"; 
POSIX::tzset(); 
$time = POSIX::mktime($s,$m,$h,$d,$mo-1,$y-1900); 

Answer 11

Para mayor referencia, un un trazador de líneas que se puede aplicar en, por ejemplo, !#/bin/sh scripts.

EPOCH="`perl -e 'use Time::Local; print timelocal('${SEC}','${MIN}','${HOUR}','${DAY}','${MONTH}','${YEAR}'),\"\n\";'`" 

Sólo recuerde para evitar valores octales!

Answer 12

Sé que esta es una pregunta antigua, pero pensé en ofrecer otra respuesta.

Time::Piece es núcleo como de Perl 5.9.5

Esto permite el análisis de tiempo en formatos elección a través del método de strptime.

ej .:

my $t = Time::Piece->strptime("Sunday 3rd Nov, 1943", 
           "%A %drd %b, %Y"); 

La parte útil es - porque es un objeto sobrecargado, puede utilizarlo para comparaciones numéricas.

p. Ej.

if ($t < time()) { #do something } 

O si se accede a él en un contexto de cadena:

print $t,"\n"; 

que se obtiene:

Wed Nov 3 00:00:00 1943 

Hay un montón de métodos de acceso que permiten algunas otras transformadas basadas tiempo útil surtidos . https://metacpan.org/pod/Time::Piece