Cómo distribuir un evento con los datos agregados - AS3

Question

cualquiera puede dar un ejemplo sencillo de cómo distribuir un evento en ActionScript3 con un objeto que se le atribuye, como

dispatchEvent(new Event(GOT_RESULT,result)); 

Aquí result es un objeto que Quiero pasar junto con el evento.

Answer 1

En caso de que desee pasar un objeto a través de un evento, debe crear un evento personalizado. El código debería ser algo como esto.

public class MyEvent extends Event 
{ 
    public static const GOT_RESULT:String = "gotResult"; 

    // this is the object you want to pass through your event. 
    public var result:Object; 

    public function MyEvent(type:String, result:Object, bubbles:Boolean=false, cancelable:Boolean=false) 
    { 
     super(type, bubbles, cancelable); 
     this.result = result; 
    } 

    // always create a clone() method for events in case you want to redispatch them. 
    public override function clone():Event 
    { 
     return new MyEvent(type, result, bubbles, cancelable); 
    } 
} 

continuación, puede utilizar el código anterior como esto:

dispatchEvent(new MyEvent(MyEvent.GOT_RESULT, result)); 

Y detectar este evento cuando sea necesario.

addEventListener(MyEvent.GOT_RESULT, myEventHandler); 
// more code to follow here... 
protected function myEventHandler(event:MyEvent):void 
{ 
    var myResult:Object = event.result; // this is how you use the event's property. 
} 

Answer 2

Si está diseñado correctamente, no debería tener que pasar un objeto al evento.
En su lugar, debe hacer una var pública en la clase de despacho.

public var myObject:Object; 

// before you dispatch the event assign the object to your class var 
myObject = ....// whatever it is your want to pass 
// When you dispatch an event you can do it with already created events or like Tomislav wrote and create a custom class. 

// in the call back just use currentTarget 
public function myCallBackFunction(event:Event):void{ 

    // typecast the event target object 
    var myClass:myClassThatDispatchedtheEvent = event.currentTarget as myClassThatDispatchedtheEvent 
    trace(myClass.myObject)// the object or var you want from the dispatching class. 

Answer 3

Este post es un poco viejo, pero si puede ayudar a alguien, puede utilizar la clase DataEvent así:

dispatchEvent(new DataEvent(YOUR_EVENT_ID, true, false, data)); 

Documentation