Pasar una variable URL a xsl

Question

¿Es posible pasar una variable URL a xsl.

EG. http: www.somedomain.com/index.aspx miVar = prueba & myvar2 = anotherTest

Me gustaría ser capaz de utilizar los valores de miVar y myvar2 en la lógica de mi archivo XSL?. Gracias.

Answer 1

Claro, puedes. Use el elemento xsl:param en el elemento xsl:stylesheet y pase el parámetro de su motor XSL.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:param name="url"/> 

Luego use string-funciones, por ejemplo:

<xsl:variable name="right-part" select="substring-after($url, 'myVar=')"/> 
<xsl:value-of select="substring-before(substring-before($right-part, 'myVar2='), '&amp;')"/> 
<xsl:text>|</xsl:text> 
<xsl:value-of select="substring-after($right-part, 'myVar2=')"/> 

Answer 2

Aquí es una transformación más genérico que obtiene cualquier número de parámetros de cadena de consulta a partir de una determinada URL:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:param name="pUrl" select= 
"'http:www.somedomain.com/index.aspx?myVar=test&amp;myVar2=anotherTest&amp;myVar3=yetAnotherTest'"/> 

<xsl:template match="/"> 
    <xsl:call-template name="GetQueryStringParams"/> 
</xsl:template> 

<xsl:template name="GetQueryStringParams"> 
    <xsl:param name="pUrl" select="$pUrl"/> 

     <xsl:variable name="vQueryPart" select= 
     "substring-before(substring-after(concat($pUrl,'?'), 
             '?'), 
         '?')"/> 

     <xsl:variable name="vHeadVar" select= 
     "substring-before(concat($vQueryPart,'&amp;'), '&amp;')"/> 

     <xsl:element name="{substring-before($vHeadVar, '=')}"> 
     <xsl:value-of select="substring-after($vHeadVar, '=')"/> 
     </xsl:element> 

    <xsl:variable name="vRest" select="substring-after($vQueryPart, '&amp;')"/> 

    <xsl:if test="string-length($vRest) > 0"> 
     <xsl:call-template name="GetQueryStringParams"> 
     <xsl:with-param name="pUrl" select= 
     "concat('?', substring(substring-after($vQueryPart, $vHeadVar), 2))"/> 
     </xsl:call-template> 
    </xsl:if> 
</xsl:template> 
</xsl:stylesheet> 

cuando esta transformación se aplica en cualquier documento XML (no utilizado), el resultado correcto y deseado se produce:

<myVar>test</myVar> 
<myVar2>anotherTest</myVar2> 
<myVar3>yetAnotherTest</myVar3>