scons: anulando las opciones de compilación para un archivo

Question

Pregunta fácil, pero no sé la respuesta.

Digamos que tengo una compilación scons donde mi CCFLAGS incluye -O1. Tengo un archivo needsOptimization.cpp donde me gustaría sobrescribir el -O1 con -O2 en su lugar. ¿Cómo podría hacer esto en scons? actualización

---

: esto es lo que terminé haciendo en base a la respuesta de bialix:

en mi archivo SConscript:

Import('env'); 

env2 = env.Clone(); 
env2.Append(CCFLAGS=Split('-O2 --asm_listing')); 

sourceFiles = ['main.cpp','pwm3phase.cpp']; 
sourceFiles2 = ['serialencoder.cpp','uartTestObject.cpp']; 
objectFiles = []; 
objectFiles.append(env.Object(sourceFiles)); 
objectFiles.append(env2.Object(sourceFiles2)); 
    ... 

previamente este archivo fue:

Import('env'); 

sourceFiles = ['main.cpp','pwm3phase.cpp','serialencoder.cpp','uartTestObject.cpp']; 
objectFiles = env.Object(sourceFiles); 
    ... 

Answer 1

Utilice el constructor Objeto() para obtener un control detallado de la compilación, d luego pasa estos objetos al desarrollador de Programa().

E.g. en lugar de:

env = Environment() 
env.Program(target='foo', source=['foo.cpp', 'bar.cpp', 'needsOptimisation.cpp']) 

Es necesario utilizar siguiente:

env = Environment() 
env_o1 = env.Clone() 
env_o1.Append(CCFLAGS = '-O1') 

env_o2 = env.Clone() 
env_o2.Append(CCFLAGS = '-O2') 

# extend these lists if needed 
SRC_O1 = ['foo.cpp', 'bar.cpp'] 
SRC_O2 = ['needsOptimisation.cpp'] 

obj_o1 = [env_o1.Object(i) for i in SRC_O1] 
obj_o2 = [env_o2.Object(i) for i in SRC_O2] 

env.Program(target='foo', source=obj_o1+obj_o2) 

Usted puede evitar la creación de clon separada de variable de entorno si se proporciona CCFLAGS = '- O2' justo en la llamada Object():

obj_o2 = [env.Object(i, CCFLAGS=env['CCFLAGS'] + ['-O2']) for i in SRC_O2] 

Answer 2

Evitar la creación de una variable env separada requiere (ref: bialix's answer) necesita algo como esto.

obj_o2 = env.Object(SRC_O2, CCFLAGS=env['CCFLAGS'] + ['-O2']); 

Si usted acaba de hacer esto (o en el bucle for como bialix hace)

obj_o2 = env.Object(SRC_O2, CCFLAGS='-O2'); 

, entonces perder todas las banderas incorporadas.